Wolfram Language & System Documentation Center

RegionIntersection

RegionIntersection[reg₁,reg₂,…]

gives the intersection of the regions reg₁, reg₂, ….

Details and Options

A point p belongs to RegionIntersection[reg₁,reg₂,…] if it belongs to all reg_i.

RegionIntersection takes the same options as Region.

Examples

open all close all

Basic Examples (2)

Intersection of two disks:

Wolfram Language code: ℛ = RegionIntersection[Disk[{0, 0}, 2], Disk[{0, 3}, 2]];

Visualize it:

Wolfram Language code: Region[ℛ]

Intersection of two MeshRegion objects:

Wolfram Language code: RegionIntersection[[image], [image]]

Scope (16)

Special Regions (7)

For some regions, intersection is computed explicitly:

Wolfram Language code:

Subscript[ℛ, 1] = Triangle[{{0, 0}, {2, 3}, {-2, 3}}];
Subscript[ℛ, 2] = Triangle[{{0, 2}, {2, -1}, {-2, -1}}];

Wolfram Language code: Subscript[ℛ, 3] = RegionIntersection[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Visualize the intersection:

Wolfram Language code: Graphics[{Opacity[0.5], {Red, Subscript[ℛ, 1]}, {Green, Subscript[ℛ, 2]}, {Blue, Subscript[ℛ, 3]}}]

An intersection of an infinite line and a ball:

Wolfram Language code:

Subscript[ℛ, 1] = InfiniteLine[{{-1, -2, -3}, {1, 2, 3}}];
Subscript[ℛ, 2] = Ball[{0, 0, 0}, 3];

Wolfram Language code: Subscript[ℛ, 3] = RegionIntersection[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Visualize the intersection:

Wolfram Language code: Graphics3D[{Opacity[0.5], {Red, Subscript[ℛ, 1]}, {Green, Subscript[ℛ, 2]}, {Blue, Subscript[ℛ, 3]}}]

An intersection of Line regions:

Wolfram Language code: ℛ = RegionIntersection[Line[{{1}, {3}}], Line[{{2}, {4}}]]

Visualize it:

Wolfram Language code: Region[ℛ]

An intersection of Polygon regions:

Wolfram Language code:

ℛ1 = Polygon[{{0, 0}, {-1, 3}, {0, 2}, {1, 3}}];
ℛ2 = Polygon[{{0, 5}, {1, 2}, {0, 3}, {-1, 2}}];

Wolfram Language code: ℛ = RegionIntersection[ℛ1, ℛ2];

Visualize it:

Wolfram Language code: Region[ℛ]

An intersection of two Disk regions:

Wolfram Language code: ℛ = RegionIntersection[Disk[{0, 0}, 1], Disk[{0, 1}, 1]];

Visualize it:

Wolfram Language code: Region[ℛ]

An intersection of a cuboid a cone:

Wolfram Language code: ℛ = RegionIntersection[Cuboid[], Cone[]];

Visualize it:

Wolfram Language code: Region[ℛ]

An intersection of regions with different RegionDimension:

Wolfram Language code: ℛ = RegionIntersection[Disk[{0, 0}, 1], Circle[{0, 1}, 1]]

Visualize it:

Wolfram Language code: Region[ℛ]

Formula Regions (2)

An intersection of ImplicitRegion objects is an ImplicitRegion:

Wolfram Language code:

Subscript[ℛ, 1] = ImplicitRegion[x ≤ 1, {x}];
Subscript[ℛ, 2] = ImplicitRegion[x ≥ -1, {x}];

Wolfram Language code: RegionIntersection[Subscript[ℛ, 1], Subscript[ℛ, 2]]

2D:

Wolfram Language code:

Subscript[ℛ, 1] = ImplicitRegion[x^2 + y^2 ≤ 1, {x, y}];
Subscript[ℛ, 2] = ImplicitRegion[x^2 + (y - 1)^2 ≤ 1, {x, y}];

Wolfram Language code: RegionIntersection[Subscript[ℛ, 1], Subscript[ℛ, 2]]

3D:

Wolfram Language code:

Subscript[ℛ, 1] = ImplicitRegion[x^2 + y^2 + z^2 ≤ 1, {x, y, z}];
Subscript[ℛ, 2] = ImplicitRegion[(x - 1)^2 + y^2 + z^2 ≤ 1, {x, y, z}];

Wolfram Language code: RegionIntersection[Subscript[ℛ, 1], Subscript[ℛ, 2]]

nD:

Wolfram Language code:

Subscript[ℛ, 1] = ImplicitRegion[x^2 + y^2 + z^2 + u^2 + v^2 ≤ 1, {x, y, z, u, v}];
Subscript[ℛ, 2] = ImplicitRegion[(x - 1)^2 + y^2 + z^2 + u^2 + v^2 ≤ 1, {x, y, z, u, v}];

Wolfram Language code: RegionIntersection[Subscript[ℛ, 1], Subscript[ℛ, 2]]

An intersection of ParametricRegion objects:

Wolfram Language code:

Subscript[ℛ, 1] = ParametricRegion[{u, v}, {{u, 0, 2}, {v, 0, 2}}];
Subscript[ℛ, 2] = ParametricRegion[{u + 1, v + 1}, {{u, 0, 2}, {v, 0, 2}}];

Wolfram Language code: ℛ = RegionIntersection[Subscript[ℛ, 1], Subscript[ℛ, 2]];

Visualize it:

Wolfram Language code: Region[ℛ]

Mesh Regions (2)

An intersection of BoundaryMeshRegion objects is a BoundaryMeshRegion:

Wolfram Language code: RegionIntersection[[image], [image]]

Wolfram Language code: BoundedRegionQ[%]

2D:

Wolfram Language code: RegionIntersection[[image], [image]]

Wolfram Language code: BoundedRegionQ[%]

3D:

Wolfram Language code: RegionIntersection[[image], [image]]

Wolfram Language code: BoundedRegionQ[%]

An intersection of full-dimensional MeshRegion objects is a MeshRegion:

Wolfram Language code: RegionIntersection[[image], [image]]

Wolfram Language code: MeshRegionQ[%]

2D:

Wolfram Language code: RegionIntersection[[image], [image]]

Wolfram Language code: MeshRegionQ[%]

3D:

Wolfram Language code: RegionIntersection[[image], [image]]

Wolfram Language code: MeshRegionQ[%]

Derived Regions (2)

An intersection of BooleanRegion objects:

Wolfram Language code:

Subscript[ℛ, 1] = BooleanRegion[Or, {Triangle[{{0, 0}, {2, 3}, {-2, 3}}], Triangle[{{0, 2}, {2, -1}, {-2, -1}}]}];
Subscript[ℛ, 2] = BooleanRegion[And, {Triangle[{{0, 0}, {2, 3}, {-2, 3}}], Triangle[{{0, 2}, {2, -1}, {-2, 2}}]}];

Wolfram Language code: ℛ = RegionIntersection[Subscript[ℛ, 1], Subscript[ℛ, 2]];

Visualize it:

Wolfram Language code: Region[ℛ]

An intersection of TransformedRegion objects:

Wolfram Language code:

Subscript[ℛ, 1] = TransformedRegion[Cuboid[], RotationTransform[Pi / 8, {1, 0, 0}]];
Subscript[ℛ, 2] = TransformedRegion[Cuboid[], RotationTransform[Pi / 8, {0, 1, 0}]];

Wolfram Language code: ℛ = RegionIntersection[Subscript[ℛ, 1], Subscript[ℛ, 2]];

Visualize it:

Wolfram Language code: Region[ℛ]

CSG Regions (2)

A intersection of CSGRegion objects in 2D:

Wolfram Language code:

Subscript[ℛ, 1] = CSGRegion[{Rectangle[{-1, -8}, {1, 8}], Rectangle[{-3, -8}, {-5, 8}], Rectangle[{-7, -8}, {-9, 8}], Rectangle[{3, -8}, {5, 8}], Rectangle[{7, -8}, {9, 8}]}];
Subscript[ℛ, 2] = CSGRegion["Difference", {Disk[{0, 0}, 8], Disk[{0, 0}, 4]}];

Wolfram Language code: RegionIntersection[Subscript[ℛ, 1], Subscript[ℛ, 2]]

A intersection of CSGRegion objects in 3D:

Wolfram Language code:

Subscript[ℛ, 1] = CSGRegion[{Cube[1.5], Cube[{0, 0, 1}, 0.8]}];
Subscript[ℛ, 2] = CSGRegion[{Ball[], Ball[{0, 0, 1}, 0.5]}];

Wolfram Language code: RegionIntersection[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Subdivision Regions (1)

A intersection of SubdivisionRegion objects in 2D:

Wolfram Language code:

Subscript[ℛ, 1] = SubdivisionRegion[Rectangle[]];
Subscript[ℛ, 2] = SubdivisionRegion[Rectangle[{1 / 2, 1 / 2}]];

Wolfram Language code: RegionIntersection[Subscript[ℛ, 1], Subscript[ℛ, 2]]

3D:

Wolfram Language code:

Subscript[ℛ, 1] = SubdivisionRegion[Cube[]];
Subscript[ℛ, 2] = SubdivisionRegion[Cube[{1 / 4, 0, 0}]];

Wolfram Language code: RegionIntersection[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Applications (3)

Intersection of regions:

Wolfram Language code: {Subscript[ℛ, 1], Subscript[ℛ, 2]} = {[image], [image]};

Wolfram Language code:

Multicolumn[Table[RegionIntersection[Subscript[ℛ, 1], TransformedRegion[Subscript[ℛ, 2], TranslationTransform[{0, 0, t}]]], {t, 0, 1, 0.2}], 3, Appearance -> "Horizontal" ]

Define a disk segment as an intersection of a disk and a half-plane:

Wolfram Language code: segment = RegionIntersection[Disk[{0, 0}, 1], HalfPlane[{{0.5, 0}, {0.5, 1}}, {1, 0}]];

Wolfram Language code: Show[{Region[Style[Disk[], LightRed]], Region[segment]}]

Define a new basic region diskSegment that uses the same notation as Disk does for disk sectors, so that diskSegment[{x,y},r,{θ₁,θ₂}] represents the disk segment from θ₁ to θ₂. Do it by writing it as a RegionIntersection of a Disk and a HalfPlane:

Wolfram Language code:

diskSegment[{x0_, y0_}, r_, {θ1_, θ2_}] := 
	Module[{ϕ1, ϕ2, ϕmid}, 
	If[θ1 < θ2, {ϕ1, ϕ2} = {θ1, θ2}, {ϕ1, ϕ2} = {θ1, θ2 + 2π}];
	ϕmid = (ϕ1 + ϕ2) / 2;
	RegionIntersection[Disk[{x0, y0}, r], 
	HalfPlane[{{x0 + r Cos[ϕ1], y0 + r Sin[ϕ1]}, {x0 + r Cos[ϕ2], y0 + r Sin[ϕ2]}}, {Cos[ϕmid], Sin[ϕmid]}]]
	];

This evaluates an object that is RegionQ and can be used as any other region:

Wolfram Language code: ℛ = diskSegment[{0, 0}, 1, {π / 4, -π / 2}]

Wolfram Language code: RegionMember[ℛ, {x, y}]//FullSimplify

Visualize the disk segment together with the disk:

Wolfram Language code: Show[{Region[Style[Disk[], LightRed]], Region[ℛ]}]

Properties & Relations (4)

A point p belongs to RegionIntersection[reg₁,reg₂,…] if it belongs to all reg_i:

Wolfram Language code:

Subscript[ℛ, 1] = Disk[{0, 0}, 2];
Subscript[ℛ, 2] = Disk[{0, 3}, 2];
Subscript[ℛ, 3] = RegionIntersection[Subscript[ℛ, 1], Subscript[ℛ, 2]];

Use RegionMember to test membership:

Wolfram Language code: p = {0, 1};

Wolfram Language code: RegionMember[Subscript[ℛ, 3], p] == RegionMember[Subscript[ℛ, 1], p]∧ RegionMember[Subscript[ℛ, 2], p]

RegionIntersection is a Boolean combination And of regions:

Wolfram Language code: {Subscript[ℛ, 1], Subscript[ℛ, 2]} = {[image], [image]};

Wolfram Language code: RegionIntersection[Subscript[ℛ, 1], Subscript[ℛ, 2]] == BooleanRegion[And, {Subscript[ℛ, 1], Subscript[ℛ, 2]}]

The RegionMeasure of an intersection obeys a simple formula:

Wolfram Language code:

Subscript[ℛ, 1] = Disk[{0, 0}, 1];
Subscript[ℛ, 2] = Disk[{1, 0}, 1];
Subscript[ℛ, 3] = RegionIntersection[Subscript[ℛ, 1], Subscript[ℛ, 2]];

Subtract the measure of the RegionUnion from the sum of the measures:

Wolfram Language code:

RegionMeasure[Subscript[ℛ, 3]] == RegionMeasure[Subscript[ℛ, 1]] + RegionMeasure[Subscript[ℛ, 2]] - RegionMeasure[RegionUnion[Subscript[ℛ, 1], Subscript[ℛ, 2]]]

The RegionDimension of an intersection is at most the minimum of all input dimensions:

Wolfram Language code:

Subscript[ℛ, 1] = Disk[{0, 0}, 1];
Subscript[ℛ, 2] = Circle[{1, 0}, 1];

Wolfram Language code:

RegionDimension[RegionIntersection[Subscript[ℛ, 1], Subscript[ℛ, 2]]] == Min[RegionDimension /@ {Subscript[ℛ, 1], Subscript[ℛ, 2]}]

It can be lower, however:

Wolfram Language code:

Subscript[ℛ, 1] = Disk[{0, 0}, 1];
Subscript[ℛ, 2] = Circle[{2, 0}, 1];
Subscript[ℛ, 3] = RegionIntersection[Subscript[ℛ, 1], Subscript[ℛ, 2]];

Wolfram Language code: Show[Region[Subscript[ℛ, 1]], Region[Subscript[ℛ, 2]], Graphics[{Red, Point[{1, 0}]}]]

These regions overlap only at a point, so the dimension of the intersection is 0:

Wolfram Language code: RegionDimension[Subscript[ℛ, 3]]

Possible Issues (2)

RegionIntersection is defined only for regions with the same RegionEmbeddingDimension:

Wolfram Language code:

Subscript[ℛ, 1] = Disk[];
Subscript[ℛ, 2] = Ball[{0, 0, 1}, 1];

Wolfram Language code: RegionIntersection[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Components of dimension less than the embedding dimension may be omitted:

Wolfram Language code:

Subscript[ℛ, 1] = MeshRegion[{{0, 0, 0}, {2, 0, 0}, {2, 2, 0}, {1, 1, 2}}, Tetrahedron[{1, 2, 3, 4}]];
Subscript[ℛ, 2] = MeshRegion[{{0, 0, 0}, {2, 2, 0}, {0, 2, 0}, {1, 1, 2}}, Tetrahedron[{1, 2, 3, 4}], PlotTheme -> "Web"];

Wolfram Language code: Show[{Subscript[ℛ, 1], Subscript[ℛ, 2]}]

Wolfram Language code: RegionIntersection[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Turn on a message:

Wolfram Language code: On[BooleanRegion::drc]

Wolfram Language code: RegionIntersection[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Neat Examples (1)

The intersection of two spiral polygons:

Wolfram Language code: RegionIntersection[[image], [image]]

Top

More Learning

Tech Support

Wolfram Solutions

Wolfram Solutions For Education

Get Started

Grow Your Skills

Work with Us

Educational Programs for Adults

Educational Programs for Youth

Read

RegionIntersection

Details and Options

Examples

Basic Examples (2)

Scope (16)

Special Regions (7)

Formula Regions (2)

Mesh Regions (2)

Derived Regions (2)

CSG Regions (2)

Subdivision Regions (1)

Applications (3)

Properties & Relations (4)

Possible Issues (2)

Neat Examples (1)

Text

CMS

APA

BibTeX

BibLaTeX

RegionIntersection

Details and Options

Examples

Basic Examples (2)

Scope (16)

Special Regions (7)

Formula Regions (2)

Mesh Regions (2)

Derived Regions (2)

CSG Regions (2)

Subdivision Regions (1)

Applications (3)

Properties & Relations (4)

Possible Issues (2)

Neat Examples (1)

See Also

Related Guides

History

Text

CMS

APA

BibTeX

BibLaTeX