WOLFRAM

Wolfram Language & System Documentation Center

BooleanRegion[bfunc,{reg1,reg2,…}]

represents the Boolean combination bfunc of regions reg1, reg2, ….

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Special Regions  
Formula Regions  
Mesh Regions  
Derived Regions  
Applications  
Properties & Relations  
Possible Issues  
Neat Examples  
See Also
Related Guides
History
Cite this Page

BooleanRegion

BooleanRegion[bfunc,{reg1,reg2,…}]

represents the Boolean combination bfunc of regions reg1, reg2, ….

Details and Options

Examples

open all close all

Basic Examples  (2)

The Boolean Xor of two disks:

Wolfram Language code: BooleanRegion[Xor, {Disk[{-1 / 3, 0}, 1], Disk[{1 / 3, 0}, 1]}];

Visualize it:

Wolfram Language code: Region[%]

A Boolean function applied to MeshRegion objects:

Wolfram Language code: BooleanRegion[¬#2∧#1&, {[image], [image]}]

Scope  (11)

Special Regions  (5)

A Boolean Or of Line regions:

Wolfram Language code: ℛ = BooleanRegion[Or, {Line[{{1}, {2}}], Line[{{3}, {4}}], Line[{{5}, {6}}]}];

Visualize it:

Wolfram Language code: Region[ℛ]

A BooleanCountingFunction applied to Polygon regions:

Wolfram Language code: pts = {{-5, 0}, {1, -2}, {-1, 0}, {1, 2}}; {p1, p2, p3, p4} = Polygon /@ {pts, -pts, Reverse /@ pts, -Reverse /@ pts};
Wolfram Language code: ℛ = BooleanRegion[BooleanCountingFunction[{1, 2}, 4], {p1, p2, p3, p4}];

Compute its Area:

Wolfram Language code: Area[ℛ]

A Boolean Xor of two Disk regions:

Wolfram Language code: ℛ = BooleanRegion[Xor, {Disk[{0, 0}, 1], Disk[{1, 0}, 1]}];

Visualize it:

Wolfram Language code: Region[ℛ]

A Boolean Or of two Cuboid regions:

Wolfram Language code: ℛ = BooleanRegion[Or, {Cuboid[], Cuboid[{0.5, 0.5, 0.5}]}];

Visualize it:

Wolfram Language code: Region[ℛ]

A Boolean And of regions with different RegionDimension:

Wolfram Language code: ℛ = BooleanRegion[And, {Disk[{0, 0}, 1], Circle[{0, 1}, 1]}];

Visualize it:

Wolfram Language code: Region[ℛ]

Formula Regions  (2)

A Boolean Xor of ImplicitRegion objects is an ImplicitRegion:

Wolfram Language code: Subscript[ℛ, 1] = ImplicitRegion[x ≤ 1, {x}]; Subscript[ℛ, 2] = ImplicitRegion[x ≥ -1, {x}];
Wolfram Language code: BooleanRegion[Xor, {Subscript[ℛ, 1], Subscript[ℛ, 2]}]

2D:

Wolfram Language code: Subscript[ℛ, 1] = ImplicitRegion[x^2 + y^2 ≤ 1, {x, y}]; Subscript[ℛ, 2] = ImplicitRegion[x^2 + (y - 1)^2 ≤ 1, {x, y}];
Wolfram Language code: BooleanRegion[Xor, {Subscript[ℛ, 1], Subscript[ℛ, 2]}]

3D:

Wolfram Language code: Subscript[ℛ, 1] = ImplicitRegion[x^2 + y^2 + z^2 ≤ 1, {x, y, z}]; Subscript[ℛ, 2] = ImplicitRegion[(x - 1)^2 + y^2 + z^2 ≤ 1, {x, y, z}];
Wolfram Language code: BooleanRegion[Xor, {Subscript[ℛ, 1], Subscript[ℛ, 2]}]

nD:

Wolfram Language code: Subscript[ℛ, 1] = ImplicitRegion[x^2 + y^2 + z^2 + u^2 + v^2 ≤ 1, {x, y, z, u, v}]; Subscript[ℛ, 2] = ImplicitRegion[(x - 1)^2 + y^2 + z^2 + u^2 + v^2 ≤ 1, {x, y, z, u, v}];
Wolfram Language code: BooleanRegion[Xor, {Subscript[ℛ, 1], Subscript[ℛ, 2]}]

A Boolean function applied to ParametricRegion objects:

Wolfram Language code: Subscript[ℛ, 1] = ParametricRegion[{u, v, w}, {{u, 0, 2}, {v, 0, 2}, {w, 0, 2}}]; Subscript[ℛ, 2] = ParametricRegion[{u - 1, v + 1, w - 1}, {{u, 0, 2}, {v, 0, 2}, {w, 0, 2}}];
Wolfram Language code: ℛ = BooleanRegion[¬#1∧#2&, {Subscript[ℛ, 1], Subscript[ℛ, 2]}];

Visualize it:

Wolfram Language code: Region[ℛ]

Mesh Regions  (2)

A Boolean function of BoundaryMeshRegion objects is a BoundaryMeshRegion:

Wolfram Language code: BooleanRegion[¬#2∧#1&, {[image], [image]}]
Wolfram Language code: BoundedRegionQ[%]

2D:

Wolfram Language code: BooleanRegion[¬#2∧#1&, {[image], [image]}]
Wolfram Language code: BoundedRegionQ[%]

3D:

Wolfram Language code: BooleanRegion[¬#2∧#1&, {[image], [image]}]
Wolfram Language code: BoundedRegionQ[%]

A Boolean function of full dimensional MeshRegion objects is a MeshRegion:

Wolfram Language code: BooleanRegion[¬#2∧#1&, {[image], [image]}]
Wolfram Language code: MeshRegionQ[%]

2D:

Wolfram Language code: BooleanRegion[¬#2∧#1&, {[image], [image]}]
Wolfram Language code: MeshRegionQ[%]

3D:

Wolfram Language code: BooleanRegion[¬#2∧#1&, {[image], [image]}]
Wolfram Language code: MeshRegionQ[%]

Derived Regions  (2)

A Boolean function of BooleanRegion objects:

Wolfram Language code: Subscript[ℛ, 1] = BooleanRegion[Or, {Triangle[{{0, 0}, {2, 3}, {-2, 3}}], Triangle[{{0, 2}, {2, -1}, {-2, -1}}]}]; Subscript[ℛ, 2] = BooleanRegion[And, {Triangle[{{0, 0}, {2, 3}, {-2, 3}}], Triangle[{{0, 2}, {2, -1}, {-2, 2}}]}];
Wolfram Language code: ℛ = BooleanRegion[¬#2∧#1&, {Subscript[ℛ, 1], Subscript[ℛ, 2]}];

Visualize it:

Wolfram Language code: Region[ℛ]

A Boolean Or of TransformedRegion objects:

Wolfram Language code: Subscript[ℛ, 1] = TransformedRegion[Cuboid[], RotationTransform[Pi / 8, {1, 0, 0}]]; Subscript[ℛ, 2] = TransformedRegion[Cuboid[], RotationTransform[Pi / 8, {0, 1, 0}]];
Wolfram Language code: ℛ = BooleanRegion[Or, {Subscript[ℛ, 1], Subscript[ℛ, 2]}];

Visualize it:

Wolfram Language code: Region[ℛ]

Applications  (1)

Boolean operations over regions:

Wolfram Language code: {a, b} = {[image], [image]};
Wolfram Language code: Multicolumn[Table[BooleanRegion[op, {a, b}, PlotLabel -> op, BaseStyle -> Opacity[0.7]], {op, {Or, And, ¬#2∧#1&, #1⊻#2&}}], 2]

Properties & Relations  (2)

RegionUnion is a Boolean combination Or of regions:

Wolfram Language code: {Subscript[ℛ, 1], Subscript[ℛ, 2]} = {[image], [image]};
Wolfram Language code: RegionUnion[Subscript[ℛ, 1], Subscript[ℛ, 2]] == BooleanRegion[Or, {Subscript[ℛ, 1], Subscript[ℛ, 2]}]

RegionIntersection:

Wolfram Language code: RegionIntersection[Subscript[ℛ, 1], Subscript[ℛ, 2]] == BooleanRegion[And, {Subscript[ℛ, 1], Subscript[ℛ, 2]}]

RegionDifference:

Wolfram Language code: RegionDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]] == BooleanRegion[¬#2∧#1&, {Subscript[ℛ, 1], Subscript[ℛ, 2]}]

RegionSymmetricDifference:

Wolfram Language code: RegionSymmetricDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]] == BooleanRegion[Xor, {Subscript[ℛ, 1], Subscript[ℛ, 2]}]

The RegionMeasure of a Boolean And obeys a simple formula:

Wolfram Language code: Subscript[ℛ, 1] = Disk[{0, 0}, 1]; Subscript[ℛ, 2] = Disk[{1, 0}, 1]; Subscript[ℛ, 3] = BooleanRegion[And, {Subscript[ℛ, 1], Subscript[ℛ, 2]}];

Subtract the measure of the RegionUnion from the sum of the measures:

Wolfram Language code: RegionMeasure[Subscript[ℛ, 3]] == RegionMeasure[Subscript[ℛ, 1]] + RegionMeasure[Subscript[ℛ, 2]] - RegionMeasure[RegionUnion[Subscript[ℛ, 1], Subscript[ℛ, 2]]]

Possible Issues  (3)

BooleanRegion is defined only for regions with the same RegionEmbeddingDimension:

Wolfram Language code: Subscript[ℛ, 1] = Disk[]; Subscript[ℛ, 2] = Ball[{0, 0, 1}, 1];
Wolfram Language code: BooleanRegion[Or, {Subscript[ℛ, 1], Subscript[ℛ, 2]}]

Components of dimension less than the embedding dimension may be omitted:

Wolfram Language code: Subscript[ℛ, 1] = MeshRegion[{{0, 0, 0}, {2, 0, 0}, {2, 2, 0}, {1, 1, 2}}, Tetrahedron[{1, 2, 3, 4}]]; Subscript[ℛ, 2] = MeshRegion[{{0, 0, 0}, {2, 2, 0}, {0, 2, 0}, {1, 1, 2}}, Tetrahedron[{1, 2, 3, 4}], PlotTheme -> "Web"];
Wolfram Language code: Show[{Subscript[ℛ, 1], Subscript[ℛ, 2]}]
Wolfram Language code: BooleanRegion[And, {Subscript[ℛ, 1], Subscript[ℛ, 2]}]

Turn on a message:

Wolfram Language code: On[BooleanRegion::drc]
Wolfram Language code: BooleanRegion[And, {Subscript[ℛ, 1], Subscript[ℛ, 2]}]

BooleanRegion may include overlapping lower-dimensional components:

Wolfram Language code: Subscript[ℛ, 1] = Sphere[]; Subscript[ℛ, 2] = Ball[{1 / 2, 0, 0}];
Wolfram Language code: Graphics3D[{Yellow, Subscript[ℛ, 1], Green, Opacity@.5, Subscript[ℛ, 2]}]
Wolfram Language code: Subscript[ℛ, 3] = BooleanRegion[Or, {DiscretizeGraphics[Subscript[ℛ, 1]], BoundaryDiscretizeGraphics[Subscript[ℛ, 2]]}]

The connected mesh components:

Wolfram Language code: ConnectedMeshComponents[Subscript[ℛ, 3]]

Neat Examples  (1)

The Boolean Xor of two spiral polygons:

Wolfram Language code: BooleanRegion[Xor, {[image], [image]}]
Wolfram Research (2014), BooleanRegion, Wolfram Language function, https://reference.wolfram.com/language/ref/BooleanRegion.html (updated 2017).

Text

Wolfram Research (2014), BooleanRegion, Wolfram Language function, https://reference.wolfram.com/language/ref/BooleanRegion.html (updated 2017).

CMS

Wolfram Language. 2014. "BooleanRegion." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2017. https://reference.wolfram.com/language/ref/BooleanRegion.html.

APA

Wolfram Language. (2014). BooleanRegion. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/BooleanRegion.html

BibTeX

@misc{reference.wolfram_2026_booleanregion, author="Wolfram Research", title="{BooleanRegion}", year="2017", howpublished="\url{https://reference.wolfram.com/language/ref/BooleanRegion.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_booleanregion, organization={Wolfram Research}, title={BooleanRegion}, year={2017}, url={https://reference.wolfram.com/language/ref/BooleanRegion.html}, note=[Accessed: 13-June-2026]}