WOLFRAM

Wolfram Language & System Documentation Center

RegionDifference[reg1,reg2]

gives the difference of the regions reg1 and reg2.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Special Regions  
Formula Regions  
Mesh Regions  
Derived Regions  
CSG Regions  
Subdivision Regions  
Applications  
Properties & Relations  
Possible Issues  
Neat Examples  
See Also
Related Guides
History
Cite this Page

RegionDifference

RegionDifference[reg1,reg2]

gives the difference of the regions reg1 and reg2.

Details and Options

Examples

open all close all

Basic Examples  (2)

Difference of two disks:

Wolfram Language code: RegionDifference[Disk[{0, 0}, 2], Disk[{3, 0}, 2]];

Visualize it:

Wolfram Language code: Region[%]

Difference of two MeshRegion objects:

Wolfram Language code: RegionDifference[[image], [image]]

Scope  (16)

Special Regions  (6)

For some regions, the difference is computed explicitly:

Wolfram Language code: Subscript[ℛ, 1] = Triangle[{{0, 0}, {1, 0}, {0, 1}}]; Subscript[ℛ, 2] = Disk[{3, 0}, 1];
Wolfram Language code: Subscript[ℛ, 3] = RegionDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]]

The regions are disjoint:

Wolfram Language code: Graphics[{Opacity[0.5], {Red, Subscript[ℛ, 1]}, {Green, Subscript[ℛ, 2]}, {Yellow, Subscript[ℛ, 3]}}]

Here the difference is empty:

Wolfram Language code: Subscript[ℛ, 1] = Cuboid[]; Subscript[ℛ, 2] = Ball[{0, 0, 0}, 2];
Wolfram Language code: Subscript[ℛ, 3] = RegionDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]]

The cuboid is contained in the ball:

Wolfram Language code: Graphics3D[{Opacity[0.5], {Red, Subscript[ℛ, 1]}, {Green, Subscript[ℛ, 2]}}]

A difference of Line regions:

Wolfram Language code: ℛ = RegionDifference[Line[{{1}, {4}}], Line[{{2}, {3}}]];

Visualize it:

Wolfram Language code: Region[ℛ]

A difference of Polygon regions:

Wolfram Language code: Subscript[ℛ, 1] = Polygon[{{0, 0}, {3, -1}, {2, 0}, {3, 1}}]; Subscript[ℛ, 2] = Polygon[{{5, 0}, {2, 1}, {3, 0}, {2, -1}}];
Wolfram Language code: ℛ = RegionDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]];

Visualize it:

Wolfram Language code: Region[ℛ]

A difference of two Cuboid regions:

Wolfram Language code: ℛ = RegionDifference[Cuboid[], Cuboid[{0.5, 0.5, 0.5}]];

Visualize it:

Wolfram Language code: Region[ℛ]

A difference of regions with different RegionDimension:

Wolfram Language code: ℛ = RegionDifference[Circle[{0, 0}, 1], Disk[{1, 0}, 1]];

Visualize it:

Wolfram Language code: Region[ℛ]

Formula Regions  (2)

A difference of ImplicitRegion objects is an ImplicitRegion:

Wolfram Language code: Subscript[ℛ, 1] = ImplicitRegion[x ≤ 1, {x}]; Subscript[ℛ, 2] = ImplicitRegion[x ≥ -1, {x}];
Wolfram Language code: RegionDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]]

2D:

Wolfram Language code: Subscript[ℛ, 1] = ImplicitRegion[x^2 + y^2 ≤ 1, {x, y}]; Subscript[ℛ, 2] = ImplicitRegion[x^2 + (y - 1)^2 ≤ 1, {x, y}];
Wolfram Language code: RegionDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]]

3D:

Wolfram Language code: Subscript[ℛ, 1] = ImplicitRegion[x^2 + y^2 + z^2 ≤ 1, {x, y, z}]; Subscript[ℛ, 2] = ImplicitRegion[(x - 1)^2 + y^2 + z^2 ≤ 1, {x, y, z}];
Wolfram Language code: RegionDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]]

nD:

Wolfram Language code: Subscript[ℛ, 1] = ImplicitRegion[x^2 + y^2 + z^2 + u^2 + v^2 ≤ 1, {x, y, z, u, v}]; Subscript[ℛ, 2] = ImplicitRegion[(x - 1)^2 + y^2 + z^2 + u^2 + v^2 ≤ 1, {x, y, z, u, v}];
Wolfram Language code: RegionDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]]

A difference of ParametricRegion objects:

Wolfram Language code: Subscript[ℛ, 1] = ParametricRegion[{u, v}, {{u, 0, 2}, {v, 0, 2}}]; Subscript[ℛ, 2] = ParametricRegion[{u + 1, v + 1}, {{u, 0, 2}, {v, 0, 2}}];
Wolfram Language code: ℛ = RegionDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]];

Visualize it:

Wolfram Language code: Region[ℛ]

Mesh Regions  (2)

A difference of BoundaryMeshRegion objects is a BoundaryMeshRegion:

Wolfram Language code: RegionDifference[[image], [image]]
Wolfram Language code: BoundedRegionQ[%]

2D:

Wolfram Language code: RegionDifference[[image], [image]]
Wolfram Language code: BoundedRegionQ[%]

3D:

Wolfram Language code: RegionDifference[[image], [image]]
Wolfram Language code: BoundedRegionQ[%]

A difference of full-dimensional MeshRegion objects is a MeshRegion:

Wolfram Language code: RegionDifference[[image], [image]]
Wolfram Language code: MeshRegionQ[%]

2D:

Wolfram Language code: RegionDifference[[image], [image]]
Wolfram Language code: MeshRegionQ[%]

3D:

Wolfram Language code: RegionDifference[[image], [image]]
Wolfram Language code: MeshRegionQ[%]

Derived Regions  (2)

A difference of BooleanRegion objects:

Wolfram Language code: Subscript[ℛ, 1] = BooleanRegion[Or, {Triangle[{{0, 0}, {2, 3}, {-2, 3}}], Triangle[{{0, 2}, {2, -1}, {-2, -1}}]}]; Subscript[ℛ, 2] = BooleanRegion[And, {Triangle[{{0, 0}, {2, 3}, {-2, 3}}], Triangle[{{0, 2}, {2, -1}, {-2, 2}}]}];
Wolfram Language code: ℛ = RegionDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]];

Visualize it:

Wolfram Language code: Region[ℛ]

A difference of TransformedRegion objects:

Wolfram Language code: Subscript[ℛ, 1] = TransformedRegion[Cuboid[], RotationTransform[Pi / 8, {1, 0, 0}]]; Subscript[ℛ, 2] = TransformedRegion[Cuboid[], RotationTransform[Pi / 8, {0, 1, 0}]];
Wolfram Language code: ℛ = RegionDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]];

Visualize it:

Wolfram Language code: Region[ℛ]

CSG Regions  (2)

A difference of CSGRegion objects in 2D:

Wolfram Language code: Subscript[ℛ, 1] = CSGRegion[{Disk[], Rectangle[]}]; Subscript[ℛ, 2] = CSGRegion[{Disk[{0, 0}, 1 / 2], Rectangle[{0, 0}, {1 / 2, 1 / 2}]}];
Wolfram Language code: RegionDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]]

A difference of CSGRegion objects in 3D:

Wolfram Language code: Subscript[ℛ, 1] = CSGRegion[{Cube[1.5], Cube[{0, 0, 1}, 3 / 4]}]; Subscript[ℛ, 2] = CSGRegion[{Cylinder[{{0, 0, -2}, {0, 0, 2}}, 1 / 3], Cylinder[{{-2, 0, 0}, {2, 0, 0}}, 1 / 2]}];
Wolfram Language code: RegionDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Subdivision Regions  (2)

A difference of SubdivisionRegion objects in 2D:

Wolfram Language code: Subscript[ℛ, 1] = SubdivisionRegion[Rectangle[]]; Subscript[ℛ, 2] = SubdivisionRegion[Rectangle[{1 / 2, 1 / 2}]];
Wolfram Language code: RegionDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]]

A difference of SubdivisionRegion objects in 3D:

Wolfram Language code: Subscript[ℛ, 1] = SubdivisionRegion[Cube[1]]; Subscript[ℛ, 2] = SubdivisionRegion[Tetrahedron[4]];
Wolfram Language code: RegionDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Applications  (4)

Difference of regions:

Wolfram Language code: {Subscript[ℛ, 1], Subscript[ℛ, 2]} = {[image], [image]};
Wolfram Language code: Multicolumn[Table[RegionDifference[Subscript[ℛ, 1], TransformedRegion[Subscript[ℛ, 2], TranslationTransform[{0, 0, t}]]], {t, 0, 2.5, 0.5}], 3, Appearance -> "Horizontal" ]

Define a disk annulus as the difference of two disks:

Wolfram Language code: annulus = RegionDifference[Disk[{0, 0}, 2], Disk[{0, 0}, 1]];
Wolfram Language code: Region[annulus]

The area is the difference of areas:

Wolfram Language code: Area[annulus]
Wolfram Language code: Area[Disk[{0, 0}, 2]] - Area[Disk[{0, 0}, 1]]

Define a ball shell (sometimes called spherical shell) as the generalization of an annulus to 3D:

Wolfram Language code: shell = RegionDifference[Ball[{0, 0, 0}, 2], Ball[{0, 0, 0}, 1]];
Wolfram Language code: RegionPlot3D[shell, PlotPoints -> 40, PlotStyle -> Opacity[0.5]]

The volume is the difference of volumes:

Wolfram Language code: Volume[shell]
Wolfram Language code: Volume[Ball[{0, 0, 0}, 2]] - Volume[Ball[{0, 0, 0}, 1]]

Create illusory contours:

Wolfram Language code: disks = RegionUnion[Disk[{0, 0}, 2], Disk[{6, 0}, 2], Disk[{3, 5}, 2]];
Wolfram Language code: RegionDifference[disks, Triangle[{{0, 0}, {6, 0}, {3, 5}}]]//Region

Properties & Relations  (5)

A point p belongs to RegionDifference[reg1,reg2] if it belongs to reg1 but not reg2:

Wolfram Language code: Subscript[ℛ, 1] = Disk[{0, 0}, 2]; Subscript[ℛ, 2] = Disk[{0, 3}, 2]; Subscript[ℛ, 3] = RegionDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]];

Use RegionMember to test membership:

Wolfram Language code: p = {0, 0};
Wolfram Language code: RegionMember[Subscript[ℛ, 3], p] == RegionMember[Subscript[ℛ, 1], p]∧ !RegionMember[Subscript[ℛ, 2], p]

RegionDifference is a Boolean combination ¬#2∧#1 of two regions:

Wolfram Language code: {Subscript[ℛ, 1], Subscript[ℛ, 2]} = {[image], [image]};
Wolfram Language code: RegionDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]] == BooleanRegion[¬#2∧#1&, {Subscript[ℛ, 1], Subscript[ℛ, 2]}]

RegionSymmetricDifference can be found using RegionUnion and RegionDifference:

Wolfram Language code: {Subscript[ℛ, 1], Subscript[ℛ, 2]} = {[image], [image]};
Wolfram Language code: RegionSymmetricDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]] == RegionUnion[RegionDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]], RegionDifference[Subscript[ℛ, 2], Subscript[ℛ, 1]]]

The RegionDimension of a difference is at most that of the first input:

Wolfram Language code: Subscript[ℛ, 1] = Disk[{0, 0}, 1]; Subscript[ℛ, 2] = Disk[{1, 0}, 1]; Subscript[ℛ, 3] = RegionDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]];
Wolfram Language code: RegionDimension[Subscript[ℛ, 3]] == RegionDimension[Subscript[ℛ, 1]]

It can be less, however:

Wolfram Language code: Subscript[ℛ, 1] = Disk[{0, 0}, 1]; Subscript[ℛ, 2] = ImplicitRegion[y > 0∨y < 0, {x, y}]; Subscript[ℛ, 3] = RegionDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]];

This difference is a line segment, and thus has dimension 1:

Wolfram Language code: RegionDimension[Subscript[ℛ, 3]]

If two regions are disjoint, the RegionMeasure of their difference is that of the first input:

Wolfram Language code: Subscript[ℛ, 1] = Disk[{0, 0}, 1]; Subscript[ℛ, 2] = Disk[{3, 0}, 1]; Subscript[ℛ, 3] = RegionDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]];
Wolfram Language code: RegionMeasure[Subscript[ℛ, 3]] == RegionMeasure[Subscript[ℛ, 1]]

If they overlap, you must subtract the measure of the RegionIntersection:

Wolfram Language code: Subscript[ℛ, 1] = Disk[{0, 0}, 1]; Subscript[ℛ, 2] = Disk[{1, 0}, 1]; Subscript[ℛ, 3] = RegionDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]];
Wolfram Language code: RegionMeasure[Subscript[ℛ, 3]] == RegionMeasure[Subscript[ℛ, 1]] - RegionMeasure[RegionIntersection[Subscript[ℛ, 1], Subscript[ℛ, 2]]]

Possible Issues  (1)

Difference is defined only for regions with the same RegionEmbeddingDimension:

Wolfram Language code: Subscript[ℛ, 1] = Disk[]; Subscript[ℛ, 2] = Ball[{0, 0, 1}, 1];
Wolfram Language code: RegionDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Neat Examples  (1)

The difference of two spiral polygons:

Wolfram Language code: RegionDifference[[image], [image]]
Wolfram Research (2014), RegionDifference, Wolfram Language function, https://reference.wolfram.com/language/ref/RegionDifference.html (updated 2017).

Text

Wolfram Research (2014), RegionDifference, Wolfram Language function, https://reference.wolfram.com/language/ref/RegionDifference.html (updated 2017).

CMS

Wolfram Language. 2014. "RegionDifference." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2017. https://reference.wolfram.com/language/ref/RegionDifference.html.

APA

Wolfram Language. (2014). RegionDifference. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/RegionDifference.html

BibTeX

@misc{reference.wolfram_2026_regiondifference, author="Wolfram Research", title="{RegionDifference}", year="2017", howpublished="\url{https://reference.wolfram.com/language/ref/RegionDifference.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_regiondifference, organization={Wolfram Research}, title={RegionDifference}, year={2017}, url={https://reference.wolfram.com/language/ref/RegionDifference.html}, note=[Accessed: 12-June-2026]}