WOLFRAM

Wolfram Language & System Documentation Center

RegionSymmetricDifference[reg1,reg2,…]

represents the symmetric difference of the regions reg1, reg2, ….

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Special Regions  
Formula Regions  
Mesh Regions  
Derived Regions  
CSG Regions  
Applications  
Properties & Relations  
Possible Issues  
Neat Examples  
See Also
Related Guides
History
Cite this Page

RegionSymmetricDifference

RegionSymmetricDifference[reg1,reg2,…]

represents the symmetric difference of the regions reg1, reg2, ….

Details and Options

Examples

open all close all

Basic Examples  (2)

Symmetric difference of two disks:

Wolfram Language code: RegionSymmetricDifference[Disk[{0, 0}, 2], Disk[{3, 0}, 2]];

Visualize it:

Wolfram Language code: Region[%]

Symmetric difference of two MeshRegion objects:

Wolfram Language code: RegionSymmetricDifference[[image], [image]]

Scope  (12)

Special Regions  (4)

A symmetric difference of Line regions:

Wolfram Language code: ℛ = RegionSymmetricDifference[Line[{{1}, {3}}], Line[{{2}, {4}}]];

Visualize it:

Wolfram Language code: Region[ℛ]

A symmetric difference of Polygon regions:

Wolfram Language code: Subscript[ℛ, 1] = Polygon[{{0, 0}, {3, -1}, {2, 0}, {3, 1}}]; Subscript[ℛ, 2] = Polygon[{{5, 0}, {2, 1}, {3, 0}, {2, -1}}];
Wolfram Language code: ℛ = RegionSymmetricDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]];

Visualize it:

Wolfram Language code: Region[ℛ]

A symmetric difference of two Cuboid regions:

Wolfram Language code: ℛ = RegionSymmetricDifference[Cuboid[], Cuboid[{0.5, 0.5, 0.5}]];
Wolfram Language code: Region[ℛ]

A symmetric difference of regions with different RegionDimension:

Wolfram Language code: ℛ = RegionSymmetricDifference[Circle[{0, 0}, 1], Disk[{1, 0}, 1]];

Visualize it:

Wolfram Language code: Region[ℛ]

Formula Regions  (2)

A symmetric difference of ImplicitRegion objects is an ImplicitRegion:

Wolfram Language code: Subscript[ℛ, 1] = ImplicitRegion[x ≤ -1, {x}]; Subscript[ℛ, 2] = ImplicitRegion[x ≥ 1, {x}];
Wolfram Language code: RegionSymmetricDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]]

2D:

Wolfram Language code: Subscript[ℛ, 1] = ImplicitRegion[x^2 + y^2 ≤ 1, {x, y}]; Subscript[ℛ, 2] = ImplicitRegion[x^2 + (y - 1)^2 ≤ 1, {x, y}]; RegionSymmetricDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]]

3D:

Wolfram Language code: Subscript[ℛ, 1] = ImplicitRegion[x^2 + y^2 + z^2 ≤ 1, {x, y, z}]; Subscript[ℛ, 2] = ImplicitRegion[(x - 1)^2 + y^2 + z^2 ≤ 1, {x, y, z}];
Wolfram Language code: RegionSymmetricDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]]

nD:

Wolfram Language code: Subscript[ℛ, 1] = ImplicitRegion[x^2 + y^2 + z^2 + u^2 + v^2 ≤ 1, {x, y, z, u, v}]; Subscript[ℛ, 2] = ImplicitRegion[(x - 1)^2 + y^2 + z^2 + u^2 + v^2 ≤ 1, {x, y, z, u, v}];
Wolfram Language code: RegionSymmetricDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]]

A symmetric difference of ParametricRegion objects:

Wolfram Language code: Subscript[ℛ, 1] = ParametricRegion[{u, v}, {{u, 0, 2}, {v, 0, 2}}]; Subscript[ℛ, 2] = ParametricRegion[{u + 1, v + 1}, {{u, 0, 2}, {v, 0, 2}}];
Wolfram Language code: ℛ = RegionSymmetricDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]];

Visualize it:

Wolfram Language code: Region[ℛ]

Mesh Regions  (2)

A symmetric difference of BoundaryMeshRegion objects is a BoundaryMeshRegion:

Wolfram Language code: RegionSymmetricDifference[[image], [image]]
Wolfram Language code: BoundedRegionQ[%]

2D:

Wolfram Language code: RegionSymmetricDifference[[image], [image]]
Wolfram Language code: BoundedRegionQ[%]

3D:

Wolfram Language code: RegionSymmetricDifference[[image], [image]]
Wolfram Language code: BoundedRegionQ[%]

A symmetric difference of full-dimensional MeshRegion objects is a MeshRegion:

Wolfram Language code: RegionSymmetricDifference[[image], [image]]
Wolfram Language code: MeshRegionQ[%]

2D:

Wolfram Language code: RegionSymmetricDifference[[image], [image]]
Wolfram Language code: MeshRegionQ[%]

3D:

Wolfram Language code: RegionSymmetricDifference[[image], [image]]
Wolfram Language code: MeshRegionQ[%]

Derived Regions  (2)

A symmetric difference of BooleanRegion objects:

Wolfram Language code: Subscript[ℛ, 1] = BooleanRegion[Or, {Triangle[{{0, 0}, {2, 3}, {-2, 3}}], Triangle[{{0, 2}, {2, -1}, {-2, -1}}]}]; Subscript[ℛ, 2] = BooleanRegion[And, {Triangle[{{0, 0}, {2, 3}, {-2, 3}}], Triangle[{{0, 2}, {2, -1}, {-2, 2}}]}];
Wolfram Language code: ℛ = RegionSymmetricDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]];

Visualize it:

Wolfram Language code: Region[ℛ]

A symmetric difference of TransformedRegion objects:

Wolfram Language code: Subscript[ℛ, 1] = TransformedRegion[Cuboid[], RotationTransform[Pi / 8, {1, 0, 0}]]; Subscript[ℛ, 2] = TransformedRegion[Cuboid[], RotationTransform[Pi / 8, {0, 1, 0}]];
Wolfram Language code: ℛ = RegionSymmetricDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]];

Visualize it:

Wolfram Language code: Region[ℛ]

CSG Regions  (2)

A symmetric difference of CSGRegion objects in 2D:

Wolfram Language code: Subscript[ℛ, 1] = CSGRegion[{Rectangle[{-1, -8}, {1, 8}], Rectangle[{-3, -8}, {-5, 8}], Rectangle[{-7, -8}, {-9, 8}], Rectangle[{3, -8}, {5, 8}], Rectangle[{7, -8}, {9, 8}]}]; Subscript[ℛ, 2] = CSGRegion["Difference", {Disk[{0, 0}, 8], Disk[{0, 0}, 4]}];
Wolfram Language code: RegionSymmetricDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]]

A symmetric difference of CSGRegion objects in 3D:

Wolfram Language code: Subscript[ℛ, 1] = CSGRegion[Join@@Table[Cuboid[{x - 1, y - 1, -10}, {x + 1, y + 1, 10}], {x, -10, 10, 4}, {y, -10, 10, 4}]]; Subscript[ℛ, 2] = CSGRegion[{Cuboid[{-11, -11, -10}, {11, 11, -6}], Cuboid[{-11, -11, 10}, {11, 11, 6}]}];
Wolfram Language code: RegionSymmetricDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Applications  (1)

Symmetric difference of regions:

Wolfram Language code: {Subscript[ℛ, 1], Subscript[ℛ, 2]} = {[image], [image]};
Wolfram Language code: Multicolumn[Table[RegionSymmetricDifference[Subscript[ℛ, 1], TransformedRegion[Subscript[ℛ, 2], TranslationTransform[{t, t}]]], {t, -0.5, 2, 0.5}], 3, Appearance -> "Horizontal"]

Properties & Relations  (5)

A point p belongs to RegionSymmetricDifference[reg1,reg2] if it belongs to an odd number of regi:

Wolfram Language code: Subscript[ℛ, 1] = Disk[{0, 0}, 2]; Subscript[ℛ, 2] = Disk[{0, 3}, 2]; Subscript[ℛ, 3] = RegionSymmetricDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]];

Use RegionMember to test membership:

Wolfram Language code: p = {0, 0};
Wolfram Language code: RegionMember[Subscript[ℛ, 3], p] == (RegionMember[Subscript[ℛ, 1], p] ∧!RegionMember[Subscript[ℛ, 2], p])∨(!RegionMember[Subscript[ℛ, 1], p] ∧RegionMember[Subscript[ℛ, 2], p])

RegionSymmetricDifference is a Boolean combination Xor of regions:

Wolfram Language code: {Subscript[ℛ, 1], Subscript[ℛ, 2]} = {[image], [image]};
Wolfram Language code: RegionSymmetricDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]] == BooleanRegion[Xor, {Subscript[ℛ, 1], Subscript[ℛ, 2]}]

RegionSymmetricDifference can be found using RegionUnion and RegionDifference:

Wolfram Language code: {Subscript[ℛ, 1], Subscript[ℛ, 2]} = {[image], [image]};
Wolfram Language code: RegionSymmetricDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]] == RegionUnion[RegionDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]], RegionDifference[Subscript[ℛ, 2], Subscript[ℛ, 1]]]

The RegionDimension of a symmetric difference is at most the max of the input dimensions:

Wolfram Language code: Subscript[ℛ, 1] = Disk[{0, 0}, 1]; Subscript[ℛ, 2] = Disk[{1, 0}, 1]; Subscript[ℛ, 3] = RegionSymmetricDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]];
Wolfram Language code: RegionDimension[Subscript[ℛ, 3]] == Max[RegionDimension /@ {Subscript[ℛ, 1], Subscript[ℛ, 2]}]

It can be less, however:

Wolfram Language code: Subscript[ℛ, 1] = InfiniteLine[{0, 0}, {1, 0}]; Subscript[ℛ, 2] = InfiniteLine[{0, 1}, {1, 0}]; ℛ = RegionSymmetricDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]];

This symmetric difference is two lines, and thus has dimension 1:

Wolfram Language code: RegionDimension[ℛ]

The RegionMeasure of a symmetric difference obeys a simple formula:

Wolfram Language code: Subscript[ℛ, 1] = Disk[{0, 0}, 1]; Subscript[ℛ, 2] = Disk[{1, 0}, 1]; Subscript[ℛ, 3] = RegionSymmetricDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]];

Simply subtract twice the measure of the intersection from the sum of the input measures:

Wolfram Language code: RegionMeasure[Subscript[ℛ, 3]] == RegionMeasure[Subscript[ℛ, 1]] + RegionMeasure[Subscript[ℛ, 2]] - 2RegionMeasure[RegionIntersection[Subscript[ℛ, 1], Subscript[ℛ, 2]]]

Possible Issues  (1)

Symmetric difference is defined only for regions with the same RegionEmbeddingDimension:

Wolfram Language code: Subscript[ℛ, 1] = Disk[]; Subscript[ℛ, 2] = Ball[{0, 0, 1}, 1];
Wolfram Language code: RegionSymmetricDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Neat Examples  (1)

The symmetric difference of two spiral polygons:

Wolfram Language code: RegionSymmetricDifference[[image], [image]]
Wolfram Research (2014), RegionSymmetricDifference, Wolfram Language function, https://reference.wolfram.com/language/ref/RegionSymmetricDifference.html (updated 2017).

Text

Wolfram Research (2014), RegionSymmetricDifference, Wolfram Language function, https://reference.wolfram.com/language/ref/RegionSymmetricDifference.html (updated 2017).

CMS

Wolfram Language. 2014. "RegionSymmetricDifference." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2017. https://reference.wolfram.com/language/ref/RegionSymmetricDifference.html.

APA

Wolfram Language. (2014). RegionSymmetricDifference. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/RegionSymmetricDifference.html

BibTeX

@misc{reference.wolfram_2026_regionsymmetricdifference, author="Wolfram Research", title="{RegionSymmetricDifference}", year="2017", howpublished="\url{https://reference.wolfram.com/language/ref/RegionSymmetricDifference.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_regionsymmetricdifference, organization={Wolfram Research}, title={RegionSymmetricDifference}, year={2017}, url={https://reference.wolfram.com/language/ref/RegionSymmetricDifference.html}, note=[Accessed: 13-June-2026]}