WOLFRAM

Wolfram Language & System Documentation Center

InverseTransformedRegion[reg,f,n]

represents the inverse transformed region , where reg is a region and f is a function.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Special Regions  
Formula Regions  
Mesh Regions  
Show More Show More
Derived Regions  
Geographic Regions  
CSG Regions  
Subdivision Regions  
See Also
Related Guides
History
Cite this Page

InverseTransformedRegion

InverseTransformedRegion[reg,f,n]

represents the inverse transformed region , where reg is a region and f is a function.

Details and Options

Examples

open all close all

Basic Examples  (2)

The inverse transform of a rotated rectangle:

Wolfram Language code: ℛ = InverseTransformedRegion[Rectangle[], RotationTransform[π / 4]]
Wolfram Language code: Region[ℛ]
Wolfram Language code: Area[ℛ]

The inverse image of a disk through :

Wolfram Language code: ℛ = InverseTransformedRegion[Disk[], {Indexed[#, 1] Indexed[#, 2], Indexed[#, 1] + Indexed[#, 2]}&, 2];
Wolfram Language code: Region[ℛ]

Scope  (24)

Special Regions  (9)

Some inverse transformed regions are computed explicitly:

Wolfram Language code: ℛ = InverseTransformedRegion[Disk[], ShearingTransform[Pi / 4, {1, 0}, {0, 1}]]

Visualize the transformation:

Wolfram Language code: Region[ℛ]

The inverse image of the unit cuboid through a linear-fractional transformation:

Wolfram Language code: Subscript[ℛ, 1] = Cuboid[]; 𝒯 = TransformationFunction[{{7, 5, -2, 3}, {3, -8, 9, 4}, {-8, 3, 1, -6}, {1, 0, 0, 5}}]; ℛ = InverseTransformedRegion[Subscript[ℛ, 1], 𝒯]

Visualize the transformation:

Wolfram Language code: Region[ℛ]

The inverse transform of a translated unit Disk:

Wolfram Language code: ℛ = InverseTransformedRegion[Disk[], TranslationTransform[{2, 3}]]

Visualize it:

Wolfram Language code: Region[ℛ]

The inverse transform of a sheared unit Rectangle:

Wolfram Language code: ℛ = TransformedRegion[Rectangle[], ShearingTransform[30Degree, {1, 0}, {0, 1}]]

Visualize it:

Wolfram Language code: Region[ℛ]

The inverse transform of a rotated Triangle:

Wolfram Language code: ℛ = TransformedRegion[Triangle[], RotationTransform[π / 3]]

Visualize it:

Wolfram Language code: Region[ℛ]

The inverse transform of a scaled Circle:

Wolfram Language code: ℛ = InverseTransformedRegion[Circle[], ScalingTransform[2., {1, 1}]];
Wolfram Language code: Region[ℛ]

The inverse image of the unit cube through a rotation transform:

Wolfram Language code: ℛ = InverseTransformedRegion[Cuboid[{0, 0, 0}, {1, 1, 1}], RotationTransform[Pi / 3, {1, 1, 1}], 3]

Visualize it:

Wolfram Language code: Region[ℛ]

An inverse transform of a rectangle by a linear transformation :

Wolfram Language code: ℛ = InverseTransformedRegion[Rectangle[], Function[p, {p[[1]] + p[[2]], p[[1]] - p[[2]]}]]

Visualize it:

Wolfram Language code: Region[ℛ]

Map points from a Triangle embedded in 2D into 3D by a nonlinear transformation :

Wolfram Language code: Subscript[ℛ, 1] = Triangle[{{0, 0}, {0, 1}, {1, 0}}];
Wolfram Language code: ℛ = InverseTransformedRegion[Subscript[ℛ, 1], {Indexed[#, 1] ^ 2 + Indexed[#, 2] ^ 2, Indexed[#, 3]}&, 3];

Visualize it:

Wolfram Language code: Region[ℛ]

Formula Regions  (4)

The inverse transform of a sheared ParametricRegion:

Wolfram Language code: pr = ParametricRegion[{Sin[θ], Sin[2θ]}, {{θ, 0, 2π}}];
Wolfram Language code: ℛ = InverseTransformedRegion[pr, ShearingTransform[30Degree, {1, 0}, {0, 1}]]

Visualize it:

Wolfram Language code: Region[ℛ]

The inverse transform of a rotated ParametricRegion:

Wolfram Language code: pr = ParametricRegion[{{s, (1 + t) s ^ 2 - t}, -1 ≤ s ≤ 1 && 0 ≤ t ≤ 1}, {s, t}];
Wolfram Language code: ℛ = InverseTransformedRegion[pr, RotationTransform[Pi / 4, {1, 1}]]

Visualize it:

Wolfram Language code: Region[ℛ]

The inverse transform of a sheared ImplicitRegion:

Wolfram Language code: ir = ImplicitRegion[x ^ 2 - y ^ 2 ≤ 1, {x, y}];
Wolfram Language code: ℛ = InverseTransformedRegion[ir, ShearingTransform[30Degree, {1, 0}, {0, 1}]]

Visualize it:

Wolfram Language code: Region[ℛ]

The inverse transform of a scaled ImplicitRegion:

Wolfram Language code: ir = ImplicitRegion[x^2 + y^2 + z^2 < 1 || (x + 1)^2 + y^2 + z^2 < 1, {x, y, z}];
Wolfram Language code: ℛ = InverseTransformedRegion[ir, ScalingTransform[{1, 1 / 2, 1 / 2}]]

Visualize it:

Wolfram Language code: Region[ℛ]

Mesh Regions  (2)

An inverse transform of BoundaryMeshRegion objects is a BoundaryMeshRegion:

Wolfram Language code: InverseTransformedRegion[[image], TranslationTransform[{1}]]
Wolfram Language code: BoundedRegionQ[%]

2D:

Wolfram Language code: InverseTransformedRegion[[image], ShearingTransform[30Degree, {1, 0}, {0, 1}]]
Wolfram Language code: BoundedRegionQ[%]

3D:

Wolfram Language code: InverseTransformedRegion[[image], RotationTransform[π / 3, {1, 0, 1}]]
Wolfram Language code: BoundedRegionQ[%]

An inverse transform of MeshRegion objects is a MeshRegion:

Wolfram Language code: InverseTransformedRegion[[image], TranslationTransform[{1}]]
Wolfram Language code: MeshRegionQ[%]

2D:

Wolfram Language code: InverseTransformedRegion[[image], ShearingTransform[30Degree, {1, 0}, {0, 1}]]
Wolfram Language code: MeshRegionQ[%]

3D:

Wolfram Language code: InverseTransformedRegion[[image], RotationTransform[π / 3, {1, 0, 1}]]
Wolfram Language code: MeshRegionQ[%]

Derived Regions  (5)

The inverse transform of a reflected TransformedRegion:

Wolfram Language code: tr = TransformedRegion[Cuboid[], ShearingTransform[30Degree, {1, 0, 0}, {0, 1, 1}]];
Wolfram Language code: ℛ = InverseTransformedRegion[tr, ReflectionTransform[{0, 1, 1}]]

Visualize it:

Wolfram Language code: Region[ℛ]

The inverse transform of a rotated RegionDifference:

Wolfram Language code: rd = RegionDifference[Rectangle[{0, 0}], Disk[{1, 0}, 1 / 2]];
Wolfram Language code: ℛ = InverseTransformedRegion[rd, RotationTransform[π / 4]];

Visualize it:

Wolfram Language code: Region[ℛ]

The inverse transform of a scaled RegionBoundary:

Wolfram Language code: rb = RegionBoundary[Polygon[{{0, 0}, {3, -1}, {2, 0}, {3, 1}}]];
Wolfram Language code: ℛ = InverseTransformedRegion[rb, ScalingTransform[2, {1, 1}]];

Visualize it:

Wolfram Language code: Region[ℛ]

The inverse transform of a reflected RegionProduct:

Wolfram Language code: rp = RegionProduct[Disk[{0, 0}, 1], Line[{{0}, {1}}]];
Wolfram Language code: ℛ = InverseTransformedRegion[rp, ReflectionTransform[{1, 0, 1}]];

Visualize it:

Wolfram Language code: Region[ℛ]

The inverse transform of a RegionUnion by a nonlinear transformation :

Wolfram Language code: ru = RegionUnion[Disk[{0, 0}, 2], Disk[{3, 0}, 2]];
Wolfram Language code: r1 = InverseTransformedRegion[ru, Function[p, {p[[1]] p[[2]], p[[1]] + p[[2]]}]];

Visualize it:

Wolfram Language code: Region[r1]

Geographic Regions  (2)

InverseTransformedRegion works on polygons of geographic entities:

Wolfram Language code: ℛ = Polygon[["france"]];
Wolfram Language code: InverseTransformedRegion[ℛ, RotationTransform[Pi / 3, {1, 1, 0}]]
Wolfram Language code: Region[ℛ]

Polygons with GeoPosition:

Wolfram Language code: ℛ = Polygon[GeoPosition[{{{40.083441, -88.235716}, {40.083607, -88.257488}, {40.082603, -88.257149}, {40.076136999999996, -88.25740499999999}, {40.076178, -88.270888}, {40.076516, -88.271558}, {40.083686, -88.271512}, {40.083659999999995, -88.267046}, ... 33323}, {40.098112, -88.228687}, {40.095216, -88.228627}, {40.095179, -88.238547}, {40.094480999999995, -88.238546}, {40.094508999999995, -88.23267}, {40.094106, -88.232556}, {40.090666999999996, -88.232477}, {40.090741, -88.235745}}}]];
Wolfram Language code: Region[ℛ]
Wolfram Language code: InverseTransformedRegion[ℛ, RotationTransform[Pi / 3, {1, 1, 0}]]

Polygons with GeoGridPosition:

Wolfram Language code: ℛ = Polygon[GeoGridPosition[{{{-0.9950503945490105, 1.2366760550756015}, {-0.9952074890903578, 1.2369207053693891}, {-0.9952196732768064, 1.2369073327446167}, {-0.9953160063787643, 1.236848436956935}, {-0.9954141759436825, 1.2369993898475449}, {-0. ... 197645333103}, {-0.9949098578570917, 1.2368130881428654}, {-0.9948663952535768, 1.2367477711687371}, {-0.9948714472169538, 1.2367426500757825}, {-0.9949211061652593, 1.2367089232486177}, {-0.9949439717990124, 1.236746107097628}}}, "Bonne"]];
Wolfram Language code: Region[ℛ]
Wolfram Language code: 𝒯 = InverseTransformedRegion[ℛ, RotationTransform[Pi / 3]]
Wolfram Language code: Region[𝒯]

CSG Regions  (1)

The inverse transform of linear CSGRegion:

Wolfram Language code: InverseTransformedRegion[CSGRegion["Difference", {Rectangle[{-1, -1}, {1, 1}], Rectangle[{-1 / 2, -1 / 2}]}], ScalingTransform[{1, 3}]]

Nonlinear:

Wolfram Language code: InverseTransformedRegion[CSGRegion["Difference", {Disk[], Disk[{0, 0}, 1 / 2]}], ScalingTransform[{1, 3}]]

Subdivision Regions  (1)

The inverse transform of a SubdivisionRegion in 2D:

Wolfram Language code: InverseTransformedRegion[SubdivisionRegion[Rectangle[]], ScalingTransform[{1, 3}]]

3D:

Wolfram Language code: InverseTransformedRegion[SubdivisionRegion[Cube[]], ScalingTransform[{1, 1, 3}]]
Wolfram Research (2014), InverseTransformedRegion, Wolfram Language function, https://reference.wolfram.com/language/ref/InverseTransformedRegion.html.

Text

Wolfram Research (2014), InverseTransformedRegion, Wolfram Language function, https://reference.wolfram.com/language/ref/InverseTransformedRegion.html.

CMS

Wolfram Language. 2014. "InverseTransformedRegion." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/InverseTransformedRegion.html.

APA

Wolfram Language. (2014). InverseTransformedRegion. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/InverseTransformedRegion.html

BibTeX

@misc{reference.wolfram_2026_inversetransformedregion, author="Wolfram Research", title="{InverseTransformedRegion}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/InverseTransformedRegion.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_inversetransformedregion, organization={Wolfram Research}, title={InverseTransformedRegion}, year={2014}, url={https://reference.wolfram.com/language/ref/InverseTransformedRegion.html}, note=[Accessed: 13-June-2026]}