WOLFRAM

Wolfram Language & System Documentation Center

MoleculePlot3D[mol]

creates a three-dimensional model of the molecule mol.

MoleculePlot3D[mol,patt]

creates a model of mol where all atoms and bonds matching the pattern patt are highlighted.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Options  
AtomLabels  
AtomLabelStyle  
BondLabels  
Show More Show More
BondLabelStyle  
Axes  
AxesLabel  
AxesOrigin  
AxesStyle  
ColorRules  
ImageSize  
IncludeHydrogens  
PlotLegends  
PlotTheme  
Neat Examples  
See Also
Related Guides
History
Cite this Page

MoleculePlot3D

MoleculePlot3D[mol]

creates a three-dimensional model of the molecule mol.

MoleculePlot3D[mol,patt]

creates a model of mol where all atoms and bonds matching the pattern patt are highlighted.

Details and Options

Examples

open all close all

Basic Examples  (3)

Create a molecule and plot it in 3D:

Wolfram Language code: MoleculePlot3D[Molecule["NC(=O)C[C@H](C(=O)O)N"]]

Highlight the first and third atoms:

Wolfram Language code: MoleculePlot3D[Molecule["NC(=O)C[C@H](C(=O)O)N"], {1, 3}]

Highlight all oxygen atoms:

Wolfram Language code: MoleculePlot3D[Molecule["NC(=O)C[C@H](C(=O)O)N"], Atom["O"]]

Highlight two different patterns:

Wolfram Language code: MoleculePlot3D["O=C(C1CCC1)S[C@@H]1CCC1(C)C", <|"carbonyl" -> Bond[{"C", "O"}, "Double"], "ring carbons" -> Atom["C", "RingAtomQ" -> True]|>]

Use different plot themes:

Wolfram Language code: MoleculePlot3D[Molecule["CCCC"], PlotTheme -> #]& /@ {"Wireframe", "Tubes", "BallAndStick", "SpaceFilling"}

Scope  (2)

A pattern can match one or multiple positions in a molecule:

Wolfram Language code: m = Molecule[{Atom["C"], Atom["C"], Atom["C"], Atom["O"], Atom["N"], Atom["C"], Atom["O"], Atom["N"], Atom["C"], Atom["C"], Atom["C"], Atom["O"], Atom["O"], Atom["C"], Atom["N"], Atom["C"], Atom["C"], Atom["O"], Atom["O"], Atom["C"], Atom["C"], A ... er" -> 10, "Direction" -> "Clockwise", "FiducialAtom" -> 9, "Ligands" -> {11, 5, 34}], Association["StereoType" -> "Tetrahedral", "ChiralCenter" -> 16, "Direction" -> "Counterclockwise", "FiducialAtom" -> 15, "Ligands" -> {17, 20, 40}]}]; carbonylPattern = Bond[{"C", "O"}, "Double"];

Highlight each carbonyl separately:

Wolfram Language code: MoleculePlot3D[m, carbonylPattern]

Highlight each carbonyl as a single color:

Wolfram Language code: MoleculePlot3D[m, {carbonylPattern}]

Highlight several patterns:

Wolfram Language code: MoleculePlot3D[Molecule[{Atom["C"], Atom["N"], Atom["C"], Atom["C"], Atom["C"], Atom["N"], Atom["C"], Atom["O"], Atom["C"], Atom["C"], Atom["C"], Atom["C"], Atom["H"], Atom["H"], Atom["H"], Atom["H"], Atom["H"], Atom["H"], Atom["H"], Atom["H"], Atom["H"], A ... e"], Bond[{6, 22}, "Single"], Bond[{10, 23}, "Single"], Bond[{10, 24}, "Single"], Bond[{11, 25}, "Single"], Bond[{11, 26}, "Single"], Bond[{11, 27}, "Single"], Bond[{12, 28}, "Single"], Bond[{12, 29}, "Single"], Bond[{12, 30}, "Single"]}], {1, Bond[{"C", "C"}, "Double"]}]

Options  (25)

AtomLabels  (1)

Label all atoms by their index:

Wolfram Language code: MoleculePlot3D[Molecule["2,3-dichloro-4-nitro-1H-pyrrole"], AtomLabels -> "AtomIndex"]

Label only chlorine atoms by their index:

Wolfram Language code: MoleculePlot3D[Molecule["2,3-dichloro-4-nitro-1H-pyrrole"], AtomLabels -> {Atom["Cl"] -> "AtomIndex"}]

Label non-hydrogen atoms by their hybridization:

Wolfram Language code: MoleculePlot3D[Molecule["2,3-dichloro-4-nitro-1H-pyrrole"], AtomLabels -> {Atom[Except["H"]] -> MoleculeProperty["OrbitalHybridization"]}]

AtomLabelStyle  (1)

Set all labels to have the same style:

Wolfram Language code: MoleculePlot3D[Molecule["2,3-dichloro-4-nitro-1H-pyrrole"], AtomLabels -> "AtomIndex", AtomLabelStyle -> Directive[FontSize -> 16, Blue]]

Set the label style depending on atom type:

Wolfram Language code: MoleculePlot3D[Molecule["2,3-dichloro-4-nitro-1H-pyrrole"], AtomLabels -> "AtomIndex", AtomLabelStyle -> {Atom["C"] -> Directive[16, Blue], Atom["O"] -> Directive[22, Purple, Bold], _ -> Italic}]

BondLabels  (1)

Label all bonds by their index:

Wolfram Language code: MoleculePlot3D[Molecule["2,3-dichloro-4-nitro-1H-pyrrole"], BondLabels -> "BondIndex"]

Label only bonds to chlorine atoms by their bond type:

Wolfram Language code: MoleculePlot3D[Molecule["2,3-dichloro-4-nitro-1H-pyrrole"], BondLabels -> {Bond[{"Cl", _}] -> MoleculeProperty["BondType"]}]

BondLabelStyle  (1)

Give all bond labels the same style:

Wolfram Language code: MoleculePlot3D[Molecule["2,3-dichloro-4-nitro-1H-pyrrole"], BondLabels -> "BondIndex", BondLabelStyle -> Directive[FontSize -> 22, Red]]

Label bonds differently based on their atoms:

Wolfram Language code: MoleculePlot3D[Molecule["2,3-dichloro-4-nitro-1H-pyrrole"], BondLabels -> "BondIndex", BondLabelStyle -> {Bond[{"N", _}] -> Directive[FontSize -> 22, Red], Bond[{"Cl", _}] -> Directive[FontSize -> 22, Blue]}]

Axes  (4)

By default, Axes are not drawn:

Wolfram Language code: MoleculePlot3D[Molecule["Nc1nccc(n1)c1c(C)onc1c1ccccc1"]]

Use AxesTrue to turn on axes:

Wolfram Language code: MoleculePlot3D[Molecule["Nc1nccc(n1)c1c(C)onc1c1ccccc1"], Axes -> True]

Use AxesOrigin to specify where the axes intersect:

Wolfram Language code: MoleculePlot3D[Molecule["Nc1nccc(n1)c1c(C)onc1c1ccccc1"], Axes -> True, AxesOrigin -> {0, 0, 0}]

Turn on each axis individually:

Wolfram Language code: {MoleculePlot3D[Molecule["Nc1nccc(n1)c1c(C)onc1c1ccccc1"], Axes -> {True, False, False}], MoleculePlot3D[Molecule["Nc1nccc(n1)c1c(C)onc1c1ccccc1"], Axes -> {False, True, False}], MoleculePlot3D[Molecule["Nc1nccc(n1)c1c(C)onc1c1ccccc1"], Axes -> {False, False, True}]}

AxesLabel  (3)

No axes labels are drawn by default:

Wolfram Language code: MoleculePlot3D[Molecule["Nc1nccc(n1)c1c(C)onc1c1ccccc1"], Axes -> True]

Place a label on the z axis:

Wolfram Language code: MoleculePlot3D[Molecule["Nc1nccc(n1)c1c(C)onc1c1ccccc1"], Axes -> True, AxesLabel -> z]

Specify axes labels:

Wolfram Language code: MoleculePlot3D[Molecule["Nc1nccc(n1)c1c(C)onc1c1ccccc1"], Axes -> True, AxesLabel -> {x, y, z}]

AxesOrigin  (2)

The position of the axes is determined automatically:

Wolfram Language code: MoleculePlot3D[Molecule["Nc1nccc(n1)c1c(C)onc1c1ccccc1"], Axes -> True]

Specify an explicit origin for the axes:

Wolfram Language code: MoleculePlot3D[Molecule["Nc1nccc(n1)c1c(C)onc1c1ccccc1"], Axes -> True, AxesOrigin -> {0, 0, 0}]

AxesStyle  (4)

Change the style for the axes:

Wolfram Language code: MoleculePlot3D[Molecule["Nc1nccc(n1)c1c(C)onc1c1ccccc1"], Axes -> True, AxesStyle -> Red]

Specify the style of each axis:

Wolfram Language code: MoleculePlot3D[Molecule["Nc1nccc(n1)c1c(C)onc1c1ccccc1"], Axes -> True, AxesStyle -> {{Thick, Brown}, {Thick, Blue}, {Thick, Green}}]

Use different styles for the ticks and the axes:

Wolfram Language code: MoleculePlot3D[Molecule["Nc1nccc(n1)c1c(C)onc1c1ccccc1"], Axes -> True, AxesStyle -> Green, TicksStyle -> Black]

Use different styles for the labels and the axes:

Wolfram Language code: MoleculePlot3D[Molecule["Nc1nccc(n1)c1c(C)onc1c1ccccc1"], Axes -> True, AxesStyle -> Green, LabelStyle -> Red]

ColorRules  (1)

Specify different colors for atomic elements:

Wolfram Language code: m = Molecule["Nc1nccc(n1)c1c(C)onc1c1ccccc1"]
Wolfram Language code: MoleculePlot3D[m]
Wolfram Language code: MoleculePlot3D[m, ColorRules -> {"C" -> RGBColor[0.79, 0.34, 0.5], "N" -> RGBColor[0.5, 0.51, 0.81], _ -> GrayLevel[.7]}]

ImageSize  (4)

Use named sizes, such as Tiny, Small, Medium and Large:

Wolfram Language code: {MoleculePlot3D[Molecule["Nc1nccc(n1)c1c(C)onc1c1ccccc1"], ImageSize -> Tiny], MoleculePlot3D[Molecule["Nc1nccc(n1)c1c(C)onc1c1ccccc1"], ImageSize -> Small]}

Specify the width of the plot:

Wolfram Language code: {MoleculePlot3D[Molecule["Nc1nccc(n1)c1c(C)onc1c1ccccc1"], ImageSize -> 150], MoleculePlot3D[Molecule["Nc1nccc(n1)c1c(C)onc1c1ccccc1"], AspectRatio -> 1.5, ImageSize -> 150]}

Specify the height of the plot:

Wolfram Language code: {MoleculePlot3D[Molecule["Nc1nccc(n1)c1c(C)onc1c1ccccc1"], ImageSize -> {Automatic, 150}], MoleculePlot3D[Molecule["Nc1nccc(n1)c1c(C)onc1c1ccccc1"], AspectRatio -> 2, ImageSize -> {Automatic, 150}]}

Allow the width and height to be up to a certain size:

Wolfram Language code: {MoleculePlot3D[Molecule["Nc1nccc(n1)c1c(C)onc1c1ccccc1"], ImageSize -> UpTo[200]], MoleculePlot3D[Molecule["Nc1nccc(n1)c1c(C)onc1c1ccccc1"], AspectRatio -> 2, ImageSize -> UpTo[200]]}

Use maximum sizes for the width and height:

Wolfram Language code: {MoleculePlot3D[Molecule["Nc1nccc(n1)c1c(C)onc1c1ccccc1"], ImageSize -> {UpTo[150], UpTo[100]}], MoleculePlot3D[Molecule["Nc1nccc(n1)c1c(C)onc1c1ccccc1"], AspectRatio -> 2, ImageSize -> {UpTo[150], UpTo[100]}]}

IncludeHydrogens  (1)

By default, all hydrogen atoms are shown:

Wolfram Language code: MoleculePlot3D[Molecule["2-cycloheptanol"]]

Show only the heavy atoms:

Wolfram Language code: MoleculePlot3D[Molecule["2-cycloheptanol"], IncludeHydrogens -> None]

Create a molecule with only a few explicit hydrogens and show them in 3D:

Wolfram Language code: MoleculePlot3D[Molecule["[H]C([H])=CC"], IncludeHydrogens -> "ExplicitOnly"]

PlotLegends  (1)

Use placeholders for plot legends:

Wolfram Language code: m = Molecule[{Atom["C"], Atom["N"], Atom["C"], Atom["C"], Atom["C"], Atom["N"], Atom["C"], Atom["O"], Atom["C"], Atom["C"], Atom["C"], Atom["C"], Atom["H"], Atom["H"], Atom["H"], Atom["H"], Atom["H"], Atom["H"], Atom["H"], Atom["H"], Atom["H"], A ... e"], Bond[{6, 22}, "Single"], Bond[{10, 23}, "Single"], Bond[{10, 24}, "Single"], Bond[{11, 25}, "Single"], Bond[{11, 26}, "Single"], Bond[{11, 27}, "Single"], Bond[{12, 28}, "Single"], Bond[{12, 29}, "Single"], Bond[{12, 30}, "Single"]}];
Wolfram Language code: MoleculePlot3D[m, {1, Bond[{"C", "C"}, "Double"]}, PlotLegends -> Automatic]

Use the expressions to label the highlights:

Wolfram Language code: MoleculePlot3D[m, {1, Bond[{"C", "C"}, "Double"]}, PlotLegends -> Placed["Expressions", Below]]

PlotTheme  (1)

Use different plot themes to visualize a molecule in 3D:

Wolfram Language code: m = Molecule["Nc1nccc(n1)c1c(C)onc1c1ccccc1"];
Wolfram Language code: MoleculePlot3D[m, PlotTheme -> "Tubes"]
Wolfram Language code: MoleculePlot3D[m, PlotTheme -> {"Spacefilling", "Monochrome"}]

Neat Examples  (1)

Combine a 3D molecule plot with a surface mesh using MoleculeMesh:

Wolfram Language code: With[{m = Molecule[{"O", "C", Atom["C", "HydrogenCount" -> 1], "C", "C", "C", Atom["C", "HydrogenCount" -> 1], Atom["C", "HydrogenCount" -> 1], "O", "C", "C", Atom["C", "HydrogenCount" -> 1], Atom["C", "HydrogenCount" -> 1], "C", "O", "C", "O", "N", ... ection" -> "Clockwise"], Association["StereoType" -> "Tetrahedral", "ChiralCenter" -> 29, "Direction" -> "Clockwise"], Association["StereoType" -> "DoubleBond", "StereoBond" -> {5, 6}, "Ligands" -> {4, 7}, "Value" -> "Opposite"]}}]}, Show[MoleculePlot3D[m, PlotTheme -> "Tubes"], MoleculeMesh[m, "Gaussian", BaseStyle -> Opacity[0.5]] ] ]
Wolfram Research (2019), MoleculePlot3D, Wolfram Language function, https://reference.wolfram.com/language/ref/MoleculePlot3D.html (updated 2021).

Text

Wolfram Research (2019), MoleculePlot3D, Wolfram Language function, https://reference.wolfram.com/language/ref/MoleculePlot3D.html (updated 2021).

CMS

Wolfram Language. 2019. "MoleculePlot3D." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2021. https://reference.wolfram.com/language/ref/MoleculePlot3D.html.

APA

Wolfram Language. (2019). MoleculePlot3D. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/MoleculePlot3D.html

BibTeX

@misc{reference.wolfram_2026_moleculeplot3d, author="Wolfram Research", title="{MoleculePlot3D}", year="2021", howpublished="\url{https://reference.wolfram.com/language/ref/MoleculePlot3D.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_moleculeplot3d, organization={Wolfram Research}, title={MoleculePlot3D}, year={2021}, url={https://reference.wolfram.com/language/ref/MoleculePlot3D.html}, note=[Accessed: 13-June-2026]}