ListPointPlot3D
ListPointPlot3D
ListPointPlot3D[{{x1,y1,z1},{x2,y2,z2},…}]
generates a 3D scatter plot of points with coordinates {xi,yi,zi}.
ListPointPlot3D[array]
generates a 3D scatter plot of points with a 2D array of height values.
ListPointPlot3D[{data1,data2,…}]
plots several collections of points, by default in different colors.
Details and Options
- Data values xi, yi and zi can be given in the following forms:
-
xi a real-valued number Quantity[xi,unit] a quantity with a unit Around[xi,ei] value xi with uncertainty ei Interval[{xmin,xmax}] values between xmin and xmax - Values xi, yi and zi that are not of the preceding form are taken to be missing and are not shown.
- The datai have the following forms and interpretations:
-
<"k1"{x1,y1,z1},"k2"{x2,y2,z2},…> values {{x1,y1,z1},{x2,y2,z2},…} {{x1,y1,z1}"lbl1",{x2,y2,z2}"lbl2",…}, data{"lbl1","lbl2",…} values {{x1,y1,z1},{x2,y2,z2},…} with labels {lbl1,lbl2,…} SparseArray values as a normal array QuantityArray magnitudes WeightedData unweighted values - ListPointPlot3D[Tabular[…]cspec] extracts and plots values from the tabular object using the column specification cspec.
- The following forms of column specifications cspec are allowed for plotting tabular data:
-
{colx,coly,colz} plot column z against columns x and y {{colx1,coly1,colz1},{colx2,coly2,colz2},…} plot column z1 against column x1 and y1 , z2 against x2 and y2, etc. - The following wrappers w can be used for the datai:
-
Annotation[datai,label] provide an annotation for the data Button[datai,action] define an action to execute when the data is clicked Callout[datai,label] label the data with a callout Callout[datai,label,pos] place the callout at relative position pos EventHandler[datai,…] define a general event handler for the data Hyperlink[datai,uri] make the data a hyperlink Labeled[datai,label] label the data Labeled[datai,label,pos] place the label at relative position pos Legended[datai,label] identify the data in a legend PopupWindow[datai,cont] attach a popup window to the data StatusArea[datai,label] display in the status area on mouseover Style[datai,styles] show the data using the specified styles Tooltip[datai,label] attach a tooltip to the data Tooltip[datai] use data values as tooltips - Wrappers w can be applied at multiple levels:
-
{{…,w[zi,j],…}} wrap the value zi,j in array data {…,w[{xi,yi,zi}],…} wrap the point {xi,yi,zi} w[datai] wrap the data w[{data1,…}] wrap a collection of datai w1[w2[…]] use nested wrappers - Callout, Labeled and Placed can use the following positions pos:
-
Automatic automatically placed labels Above, Below, Before, After positions around the data {pos,epos} epos in label placed at relative position pos of the data - Labels are placed on a billboard plane that always faces the camera, and Before, After, etc. refer to positions on that plane.
- ListPointPlot3D has the same options as Graphics3D, with the following additions and changes: [List of all options]
-
Axes True whether to draw axes BoxRatios {1,1,0.4} bounding 3D box ratios ColorFunction Automatic how to determine the color of points ColorFunctionScaling True whether to scale arguments to ColorFunction DataRange Automatic the range of x and y values to assume for data Filling None how to fill in stems for each point FillingStyle Automatic style to use for filling IntervalMarkers Automatic how to render uncertainty IntervalMarkersStyle Automatic style for uncertainty elements LabelingFunction Automatic how to label points LabelingSize Automatic size to use for callout and label LabelingTarget Automatic how to determine automatic label positions PerformanceGoal $PerformanceGoal aspects of performance to try to optimize PlotFit None how to fit a curve to the points PlotFitElements Automatic fitted elements to show in the plot PlotInteractivity $PlotInteractivity whether to allow interactive elements PlotLegends None legends for points PlotRange {Full,Full,Automatic} the range of z or other values to include PlotRangePadding Automatic how much to pad the range of values PlotStyle Automatic styles of points PlotTheme $PlotTheme overall theme for the plot RegionFunction (True&) how to determine whether a point should be included RegionBoundaryStyle ![TemplateBox[{Automatic, paclet:ref/Automatic}, RefLink, BaseStyle -> {3ColumnTableMod}]](Files/ListPointPlot3D.en/1.png "TemplateBox[{Automatic, paclet:ref/Automatic}, RefLink, BaseStyle -> {3ColumnTableMod}]")
style to use for a region ScalingFunctions None how to scale individual coordinates - The option setting Filling->Automatic shows stems for all points.
- DataRange determines how values {{z11, …, z1n},…,{zm1,…,zmn}} {z1q,…,zn} are interpreted into {{x11,y11,z11},…,{xmn,ymn,zmn}}. Possible settings include:
-
Automatic,All uniform from 1 to m or n {{xmin,xmax},{ymin,ymax}} uniform from xmin to xmax and from ymin to ymax - In general, a list of triples {{x1,y1,z1},{x2,y2,z2},…} is interpreted as a list of points, but the setting DataRangeAll forces it to be interpreted as multiple datai {{z11,z12,z13},{z21,z22,z23},…}.
- Typical settings for PlotLegends include:
-
None no legend Automatic automatically determine legend {lbl1,lbl2,…} use lbl1, lbl2, … as legend labels Placed[lspec,…] specify placement for legend - PlotStylesty specifies the styles to use for each curve. Possible settings include:
-
{sty1,sty2,…} sequence of styles for the datasets <"key"val,…> styling elements for different levels of data - The accepted keys are:
-
"Base" overall style for all the datai "Lists" list of styles styi for each datai - ColorData["DefaultPlotColors"] gives the default sequence of colors used by PlotStyle.
- The arguments supplied to functions in ColorFunction and RegionFunction are x, y and z. Functions in ColorFunction are by default supplied with scaled versions of these arguments.
-
AlignmentPoint Center the default point in the graphic to align with AspectRatio Automatic ratio of height to width Axes True whether to draw axes AxesEdge Automatic on which edges to put axes AxesLabel None axes labels AxesOrigin Automatic where axes should cross AxesStyle {} graphics directives to specify the style for axes Background None background color for the plot BaselinePosition Automatic how to align with a surrounding text baseline BaseStyle {} base style specifications for the graphic Boxed True whether to draw the bounding box BoxRatios {1,1,0.4} bounding 3D box ratios BoxStyle {} style specifications for the box ClipPlanes None clipping planes ClipPlanesStyle Automatic style specifications for clipping planes ColorFunction Automatic how to determine the color of points ColorFunctionScaling True whether to scale arguments to ColorFunction ContentSelectable Automatic whether to allow contents to be selected ControllerLinking False when to link to external rotation controllers ControllerPath Automatic what external controllers to try to use DataRange Automatic the range of x and y values to assume for data Epilog {} 2D graphics primitives to be rendered after the main plot FaceGrids None grid lines to draw on the bounding box FaceGridsStyle {} style specifications for face grids Filling None how to fill in stems for each point FillingStyle Automatic style to use for filling FormatType TraditionalForm default format type for text ImageMargins 0. the margins to leave around the graphic ImagePadding All what extra padding to allow for labels, etc. ImageSize Automatic absolute size at which to render the graphic IntervalMarkers Automatic how to render uncertainty IntervalMarkersStyle Automatic style for uncertainty elements LabelingFunction Automatic how to label points LabelingSize Automatic size to use for callout and label LabelingTarget Automatic how to determine automatic label positions LabelStyle {} style specifications for labels Lighting Automatic simulated light sources to use Method Automatic details of 3D graphics methods to use PerformanceGoal $PerformanceGoal aspects of performance to try to optimize PlotFit None how to fit a curve to the points PlotFitElements Automatic fitted elements to show in the plot PlotInteractivity $PlotInteractivity whether to allow interactive elements PlotLabel None a label for the plot PlotLegends None legends for points PlotRange {Full,Full,Automatic} the range of z or other values to include PlotRangePadding Automatic how much to pad the range of values PlotRegion Automatic final display region to be filled PlotStyle Automatic styles of points PlotTheme $PlotTheme overall theme for the plot PreserveImageOptions Automatic whether to preserve image options when displaying new versions of the same graphic Prolog {} 2D graphics primitives to be rendered before the main plot RegionBoundaryStyle ![TemplateBox[{Automatic, paclet:ref/Automatic}, RefLink, BaseStyle -> {3ColumnTableMod}]](Files/ListPointPlot3D.en/2.png "TemplateBox[{Automatic, paclet:ref/Automatic}, RefLink, BaseStyle -> {3ColumnTableMod}]")
style to use for a region RegionFunction (True&) how to determine whether a point should be included RotationAction "Fit" how to render after interactive rotation ScalingFunctions None how to scale individual coordinates SphericalRegion Automatic whether to make the circumscribing sphere fit in the final display area Ticks Automatic specification for ticks TicksStyle {} style specification for ticks TouchscreenAutoZoom False whether to zoom to fullscreen when activated on a touchscreen ViewAngle Automatic angle of the field of view ViewCenter Automatic point to display at the center ViewMatrix Automatic explicit transformation matrix ViewPoint {1.3,-2.4,2.} viewing position ViewProjection Automatic projection method for rendering objects distant from the viewer ViewRange All range of viewing distances to include ViewVector Automatic position and direction of a simulated camera ViewVertical {0,0,1} direction to make vertical
List of all options
Examples
open all close allBasic Examples (6)
Show a scatter plot from an array of height values:
ListPointPlot3D[Table[Sin[j ^ 2 + i], {i, 0, 3, 0.1}, {j, 0, 3, 0.1}]]data = Flatten[Table[{r Cos[t], r Sin[t], Sinc[r]}, {r, 0, 10, 0.5}, {t, 0, 2Pi, 0.1}], 1];ListPointPlot3D[data]Add labels as Callout:
ListPointPlot3D[RandomReal[1, {6, 3}] -> RandomWord[6], LabelingFunction -> Callout]ListPointPlot3D[Table[Sin[j ^ 2 + i], {i, 0, 3, 0.2}, {j, 0, 3, 0.2}], Filling -> Bottom]ListPointPlot3D[{Table[Sin[j ^ 2 + i], {i, 0, 3, 0.1}, {j, 0, 3, 0.1}], Table[Sin[j ^ 2 + i] + 3, {i, 0, 3, 0.1}, {j, 0, 3, 0.1}]}]ListPointPlot3D[Table[Sin[i]Cos[j], {i, -5, 5, .25}, {j, -5, 5, .25}], ColorFunction -> "Rainbow"]Scope (36)
General Data (8)
For regular data consisting of 
values, the 
and 
data ranges are taken to be integer values:
ListPointPlot3D[Table[Sin[j / 3], {i, 20}, {j, 20}]]Provide explicit 
and 
data ranges by using DataRange:
ListPointPlot3D[Table[Sin[j / 3], {i, 20}, {j, 20}], DataRange -> {{0, 1}, {0, 1}}]Plot multiple sets of regular data:
ListPointPlot3D[{Table[Sin[j / 3], {i, 20}, {j, 20}], Table[-Sin[j / 3], {i, 20}, {j, 20}]}]For irregular data consisting of 
triples, the 
and 
data ranges are inferred from the data:
ListPointPlot3D[Table[{i, Cos[i], Sin[i]}, {i, 0, 20, .1}]]Plot multiple sets of irregular data:
data1 = Table[{i, Cos[i], Sin[i]}, {i, 0, 20, .1}];
data2 = Table[{i, Cos[i + Pi / 2], Sin[i + Pi / 2]}, {i, 0, 20, .1}];ListPointPlot3D[{data1, data2}]Areas around where the data is nonreal are excluded:
ListPointPlot3D[ReplacePart[Partition[Range[100], 10], {{3, 3} -> None, {5, 7} -> I, {8, 4} -> Missing["NotAvailable"]}], PlotStyle -> PointSize[Large]]ListPointPlot3D[Table[Sqrt[2 - i ^ 2 - j ^ 2], {i, -2, 2, .1}, {j, -2, 2, .1}]]PlotRange is selected automatically:
ListPointPlot3D[Table[1 / (x ^ 2 + y ^ 2), {x, -2, 2, 8 / 51}, {y, -2, 2, 8 / 51}]]Use PlotRange to focus in on areas of interest:
{ListPointPlot3D[Table[x ^ 4 + y ^ 4 - x ^ 2 - y ^ 2 + 1, {x, -2, 2, 0.15}, {y, -2, 2, 0.15}]], ListPointPlot3D[Table[x ^ 4 + y ^ 4 - x ^ 2 - y ^ 2 + 1, {x, -2, 2, 0.15}, {y, -2, 2, 0.15}], PlotRange -> {0, 2}]}Use RegionFunction to restrict the surface to a region given by inequalities:
data = Flatten[Table[{x, y, Sin[x ^ 2 + y ^ 2] / (x ^ 2 + y ^ 2)}, {x, -4, 4, 0.2}, {y, -4, 4, 0.2}], 1];//QuietListPointPlot3D[data, PlotRange -> All, RegionFunction -> Function[{x, y, z}, Norm[{x, y}] < 4]]Tabular Data (2)
tab = Tabular[IconizedObject[«data»], {"x", "y", "f", "g"}]ListPointPlot3D[tab -> {"x", "y", "f"}]ListPointPlot3D[tab -> {{"x", "y", "f"}, {"x", "y", "g"}}]Include legends for the plot, using the column names:
ListPointPlot3D[tab -> {{"x", "y", "f"}, {"x", "y", "g"}}, PlotLegends -> {"f", "g"}]tab = ResourceData["Sample Tabular Data: Palmer Penguins"]Plot three columns as coordinate triples:
ListPointPlot3D[tab -> {"bill_length", "flipper_length", "body_mass"}]Use PivotToColumns to create columns of values for each species:
pivot = PivotToColumns[tab, "species" -> "bill_length"]ListPointPlot3D[pivot -> {{"Adelie", "flipper_length", "body_mass"}, {"Gentoo", "flipper_length", "body_mass"}, {"Chinstrap", "flipper_length", "body_mass"}}, AxesLabel -> {"bill length", "flipper length", "body mass"}, PlotLegends -> {"Adelie", "Gentoo", "Chinstrap"}]Special Data (6)
Use Quantity to include units with the data:
ListPointPlot3D[Quantity[RandomReal[1, {6, 3}], "Meters"], AxesLabel -> Automatic]Plot data in a QuantityArray:
data = QuantityArray[EntityValue[
EntityClass[
"Star", {EntityProperty["Star", "DistanceFromEarth"] ->
TakeSmallest[25]}], {"Mass", "Radius", "DistanceFromEarth"}]]ListPointPlot3D[data, AxesLabel -> Automatic]Specify the units used with TargetUnits:
ListPointPlot3D[data, TargetUnits -> {"Tons", Automatic, Automatic}, AxesLabel -> Automatic]zvar = Table[Around[Sin[x] Cos[y], 1], {x, -4, 4}, {y, -4, 4}];ListPointPlot3D[zvar]Specify strings to use as labels:
ListPointPlot3D[{{2 -> "a", 3 -> "b", 5 -> "c", 7 -> "d", 11 -> "e", 13 -> "f", 17 -> "g"}}]ListPointPlot3D[{{2, 3, 5, 7, 11, 13, 17} -> {"a", "b", "c", "d", "e", "f", "g"}}]ListPointPlot3D[{{2, 3, 5, 7, 11, 13, 17} -> {"a", "b", "c", "d", "e", "f", "g"}}, LabelingFunction -> Above]Plot data in a SparseArray:
ListPointPlot3D[SparseArray[{{i_, i_} -> -2, {i_, j_} /; Abs[i - j] == 1 -> 1}, {5, 5}]]Data Wrappers (6)
Use wrappers on individual data, datasets or collections of datasets:
{ListPointPlot3D[{{{1, 1, 1}, Style[{2, 2, 2}, Red], {3, 3, 3}}, {{1, 0, 1}, {2, 1, 2}, {3, 2, 3}}}, PlotStyle -> PointSize[0.05]], ListPointPlot3D[{Style[{{1, 1, 1}, {2, 2, 2}, {3, 3, 3}}, Green], {{1, 0, 1}, {2, 1, 2}, {3, 2, 3}}}, PlotStyle -> PointSize[0.05]], ListPointPlot3D[Style[{{{1, 1, 1}, {2, 2, 2}, {3, 3, 3}}, {{1, 0, 1}, {2, 1, 2}, {3, 2, 3}}}, Blue], PlotStyle -> PointSize[0.05]]}{ListPointPlot3D[{{{1, 1, 1}, Style[{2, 2, 2}, Red], {3, 3, 3}}, {{1, 0, 1}, {2, 1, 2}, {3, 2, 3}}}, PlotStyle -> PointSize[0.05]], ListPointPlot3D[{Style[{{1, 1, 1}, Style[{2, 2, 2}, Red], {3, 3, 3}}, Green], {{1, 0, 1}, {2, 1, 2}, {3, 2, 3}}}, PlotStyle -> PointSize[0.05]], ListPointPlot3D[Style[{Style[{{1, 1, 1}, Style[{2, 2, 2}, Red], {3, 3, 3}}, Green], {{1, 0, 1}, {2, 1, 2}, {3, 2, 3}}}, Blue], PlotStyle -> PointSize[0.05]]}Use the value of each point as a tooltip:
ListPointPlot3D[Tooltip[RandomReal[1, {10, 3}]]]Use a specific label for all the points:
ListPointPlot3D[Tooltip[RandomReal[1, {10, 3}], "hello"]]Labels points with automatically positioned text:
ListPointPlot3D[Table[Labeled[RandomReal[1, 3], i], {i, 20}], PlotStyle -> PointSize[Medium], ImageSize -> 300]Use PopupWindow to provide additional drilldown information:
ListPointPlot3D[{{1, 1, 1}, PopupWindow[{2, 2, 2}, DateListPlot[FinancialData["IBM", "Jan. 1, 2004"]]], {3, 3, 3}}, PlotStyle -> PointSize[0.05]]Button can be used to trigger any action:
ListPointPlot3D[{{1, 1, 1}, Button[{2, 2, 2}, Speak[2]], {3, 3, 3}}, PlotStyle -> PointSize[0.05]]Labeling and Legending (6)
Label points with automatically positioned text:
ListPointPlot3D[Table[Labeled[RandomReal[1, 3], i], {i, 20}], PlotStyle -> PointSize[Medium], ImageSize -> 300]Place the labels relative to the points:
Table[ListPointPlot3D[Table[Labeled[RandomReal[1, 3], i, p], {i, 5}], PlotLabel -> p], {p, {Above, Below, Before, After}}]Specify label names with LabelingFunction:
ListPointPlot3D[RandomReal[1, {10, 3}], LabelingFunction -> (#1[[1]] &)]Include legends for each point collection:
data = Table[Table[{x, y, f}, {x, 0, 2Pi, 0.1}, {y, 0, 2Pi, 0.1}], {f, {Sin[x + y], Sin[2x + y]}}];ListPointPlot3D[Join@@@data, PlotLegends -> {Sin[x + y], Sin[2x + y]}]Use Legended to provide a legend for a specific dataset:
{upper, lower, average} = Join@@@Table[Table[{x, y, f}, {x, 0, 2Pi, 0.1}, {y, 0, 2Pi, 0.1}], {f, {Sin[x + y], Sin[-x - y], Sin[x + y] + Sin[-x - y]}}];ListPointPlot3D[{upper, lower, Legended[average, "average"]}]Use Placed to change the legend location:
ListPointPlot3D[{upper, lower, Legended[average, Placed["average", Below]]}]Specify the maximum size of labels:
data = Table[Labeled[{RandomReal[i], RandomReal[i], RandomReal[i]}, RandomWord[]], {i, 10}];ListPointPlot3D[data, LabelingSize -> 30]ListPointPlot3D[data, LabelingSize -> Full]For dense sets of points, some labels may be turned into tooltips by default:
data = Table[Labeled[{RandomReal[i], RandomReal[i], RandomReal[i]}, i], {i, 200}];ListPointPlot3D[data]Increasing the size of the plot will show more labels:
ListPointPlot3D[data, ImageSize -> 400]Presentation (8)
Provide an explicit PlotStyle for the points:
ListPointPlot3D[Table[Sin[j ^ 2 + i], {i, -3, 3, 0.05}, {j, -3, 3, 0.05}], PlotStyle -> Directive[Orange, PointSize[Tiny]]]Provide separate styles for different surfaces:
data1 = Table[Sqrt[1 - x ^ 2 - y ^ 2], {x, -1, 1, 0.05}, {y, -1, 1, 0.1}];data2 = Table[-Sqrt[1 - x ^ 2 - y ^ 2], {x, -1, 1, 0.05}, {y, -1, 1, 0.1}];ListPointPlot3D[{data1, data2}, PlotStyle -> {Red, Blue}, BoxRatios -> Automatic, DataRange -> {{-1, 1}, {-1, 1}}]ListPointPlot3D[Table[Sin[i + j ^ 2], {i, 0, 3, 0.1}, {j, 0, 3, 0.1}], AxesLabel -> {j, i}, PlotLabel -> Sin[i + j ^ 2], PlotStyle -> Purple]ListPointPlot3D[Table[Sin[i + j ^ 2], {i, 0, 3, 0.1}, {j, 0, 3, 0.1}], ColorFunction -> Function[{x, y, z}, Hue[z]]]Provide an interactive Tooltip for each point:
ListPointPlot3D[Tooltip[Table[Sin[i + j ^ 2], {i, 0, 3, 0.1}, {j, 0, 3, 0.1}]], PlotStyle -> Darker[Green]]Provide an interactive Tooltip for the whole plot:
ListPointPlot3D[Tooltip[Table[Sin[i + j ^ 2], {i, 0, 3, 0.1}, {j, 0, 3, 0.1}], TraditionalForm@Sin[i + j ^ 2]], PlotStyle -> Darker[Green]]ListPointPlot3D[Table[Sin[i + j ^ 2], {i, 0, 3, 0.1}, {j, 0, 3, 0.1}], Filling -> Bottom, FillingStyle -> Directive[Opacity[0.3], Blue], PlotStyle -> Directive[PointSize[Tiny], Red]]Use a theme with simple ticks in a bright color scheme:
ListPointPlot3D[Table[Table[Sin[i + j ^ k], {i, 0, 3, 0.1}, {j, 0, 3, 0.1}], {k, {1, 2}}], PlotTheme -> "Business"]ListPointPlot3D[Table[Table[Sin[i + j ^ k], {i, 0, 3, 0.1}, {j, 0, 3, 0.1}], {k, {1, 2}}], PlotTheme -> "Marketing"]Options (83)
Axes (3)
By default, Axes are drawn:
ListPointPlot3D[Table[{i, Cos[i], Sin[i]}, {i, 0, 20, .1}]]Use AxesFalse to turn off axes:
ListPointPlot3D[Table[{i, Cos[i], Sin[i]}, {i, 0, 20, .1}], Axes -> False]Turn on each axis individually:
{ListPointPlot3D[Table[{i, Cos[i], Sin[i]}, {i, 0, 20, .1}], Axes -> {True, False, False}], ListPointPlot3D[Table[{i, Cos[i], Sin[i]}, {i, 0, 20, .1}], Axes -> {False, True, False}], ListPointPlot3D[Table[{i, Cos[i], Sin[i]}, {i, 0, 20, .1}], Axes -> {False, False, True}]}AxesLabel (4)
No axes labels are drawn by default:
ListPointPlot3D[Table[{i, Cos[i], Sin[i]}, {i, 0, 20, .1}], Axes -> True]
ListPointPlot3D[Table[{i, Cos[i], Sin[i]}, {i, 0, 20, .1}], Axes -> True, AxesLabel -> z]ListPointPlot3D[Table[{i, Cos[i], Sin[i]}, {i, 0, 20, .1}], Axes -> True, AxesLabel -> {x, y, z}]ListPointPlot3D[Table[{Quantity[i, "Meters"], Quantity[Cos[i], "Meters"], Quantity[Sin[i], "Meters"]}, {i, 0, 20, .1}], Axes -> True, AxesLabel -> Automatic]AxesOrigin (2)
The position of the axes is determined automatically:
ListPointPlot3D[Table[{i, Cos[i], Sin[i]}, {i, 0, 20, .1}], Axes -> True]Specify an explicit origin for the axes:
ListPointPlot3D[Table[{i, Cos[i], Sin[i]}, {i, 0, 20, .1}], Axes -> True, AxesOrigin -> {10, 0, -1}]AxesStyle (4)
Change the style for the axes:
ListPointPlot3D[Table[{i, Cos[i], Sin[i]}, {i, 0, 20, .1}], AxesStyle -> Red]Specify the style of each axis:
ListPointPlot3D[Table[{i, Cos[i], Sin[i]}, {i, 0, 20, .1}], AxesStyle -> {{Thick, Brown}, {Thick, Blue}, {Thick, Green}}]Use different styles for the ticks and the axes:
ListPointPlot3D[Table[{i, Cos[i], Sin[i]}, {i, 0, 20, .1}], AxesStyle -> Green, TicksStyle -> Red]Use different styles for the labels and the axes:
ListPointPlot3D[Table[{i, Cos[i], Sin[i]}, {i, 0, 20, .1}], AxesStyle -> Green, LabelStyle -> Red]ColorFunction (5)
Color by scaled 
, 
, and 
values:
Table[ListPointPlot3D[Table[Sin[j ^ 2 + i], {i, 0, Pi, 0.1}, {j, 0, Pi, 0.1}], ColorFunction -> Function[{x, y, z}, Evaluate[f]], PlotLabel -> f], {f, {Hue[x], Hue[y], Hue[z]}}]Color by scaled 
and 
coordinates:
ListPointPlot3D[Table[Sin[j ^ 2 + i], {i, 0, Pi, 0.1}, {j, 0, Pi, 0.1}], ColorFunction -> Function[{x, y, z}, RGBColor[x, y, 0.]]]Use ColorData for predefined color gradients:
ListPointPlot3D[Table[Sin[j ^ 2 + i], {i, 0, Pi, 0.1}, {j, 0, Pi, 0.1}], ColorFunction -> (ColorData["Rainbow"][#1]&)]Named color gradients color in the 
direction:
ListPointPlot3D[Table[Sin[j ^ 2 + i], {i, 0, Pi, 0.1}, {j, 0, Pi, 0.1}], ColorFunction -> "Rainbow"]ColorFunction has higher priority than PlotStyle:
ListPointPlot3D[Table[Sin[j ^ 2 + i], {i, 0, Pi, 0.1}, {j, 0, Pi, 0.1}], ColorFunction -> "Rainbow", PlotStyle -> Directive[Opacity[.5], Red]]ColorFunctionScaling (2)
data = Flatten[Table[{x, y, Abs[Sin[x + I y]]}, {x, -2Pi, 2Pi, Pi / 5}, {y, -2, 2, 1 / 5}], 1];ListPointPlot3D[data, ColorFunction -> Function[{x, y, z}, Hue@Rescale[Arg[Sin[x + I y]], {-Pi, Pi}]], ColorFunctionScaling -> False]Unscaled coordinates are dependent on DataRange:
data = Table[Sin[j ^ 2 + i], {i, 0, Pi, 0.1}, {j, 0, Pi, 0.1}];ListPointPlot3D[data, ColorFunction -> Function[{x, y, z}, RGBColor[x, y, 0]], ColorFunctionScaling -> False]ListPointPlot3D[data, ColorFunction -> Function[{x, y, z}, RGBColor[x, y, 0]], ColorFunctionScaling -> False, DataRange -> {{0, 1}, {0, 1}}]DataRange (5)
Arrays of height values are displayed against the number of elements in each direction:
ListPointPlot3D[Table[Sin[i + j], {i, 0, 2Pi, 0.2}, {j, 0, 2Pi, 0.2}]]Rescale to the sampling space:
ListPointPlot3D[Table[Sin[i + j], {i, 0, 2Pi, 0.2}, {j, 0, 2Pi, 0.2}], DataRange -> {{0, 2Pi}, {0, 2Pi}}]Each dataset is scaled to the same domain:
ListPointPlot3D[{Array[Times, {40, 40}], Array[700&, {30, 30}]}, DataRange -> {{0, 1}, {0, 1}}, PlotRange -> All, PlotStyle -> {Red, Blue}]Triples are interpreted as 
, 
, 
coordinates:
data = Flatten[Table[{i, j, Sin[i + j]}, {j, 0, 2Pi, 0.2}, {i, -3, 3, .5}], 1];ListPointPlot3D[data]Force interpretation as arrays of height values:
data = Table[Sin[i + j], {j, 0, 2Pi, 0.5}, {i, -1, 1}];ListPointPlot3D[data, DataRange -> All]The dataset is normally interpreted as a list of 
, 
, 
triples:
ListPointPlot3D[data]Filling (3)
Fill to the bottom, using "stems":
ListPointPlot3D[Table[Sin[j ^ 2 + i], {i, 0, Pi, 0.2}, {j, 0, Pi, 0.2}], Filling -> Bottom]Filling occurs along the region cut by the RegionFunction:
ListPointPlot3D[Table[Sin[j ^ 2 + i], {i, -Pi, Pi, 0.3}, {j, -Pi, Pi, 0.3}], Filling -> Bottom, RegionFunction -> (#1 ^ 2 + #2 ^ 2 < 5&), DataRange -> {{-Pi, Pi}, {-Pi, Pi}}]Fill surface 1 to the bottom with blue and surface 2 to the top with red:
ListPointPlot3D[Table[Cos[y] + a, {a, {-1, 1}}, {x, 0, 2Pi, .3}, {y, 0, 2Pi, .3}], Filling -> {1 -> {Bottom, Blue}, 2 -> {Top, Red}}]FillingStyle (3)
Fill to the bottom with a variety of styles:
Table[ListPointPlot3D[Table[Sin[j ^ 2 + i], {i, 0, Pi, 0.2}, {j, 0, Pi, 0.2}], Filling -> Bottom, FillingStyle -> fs], {fs, {Directive[Opacity[0.2], Blue], Directive[Red, Dashed]}}]Fill to the plane 
with orange below and blue above:
ListPointPlot3D[Table[Sin[j ^ 2 + i], {i, 0, Pi, 0.2}, {j, 0, Pi, 0.2}], Filling -> 0, FillingStyle -> {Orange, Blue}]Fill to the plane 
from above only:
ListPointPlot3D[Table[Sin[j ^ 2 + i], {i, 0, Pi, 0.2}, {j, 0, Pi, 0.2}], Filling -> 0, FillingStyle -> {None, Blue}]ImageSize (7)
Use named sizes such as Tiny, Small, Medium and Large:
{ListPointPlot3D[Table[{i, Cos[i], Sin[i]}, {i, 0, 20, .1}], ImageSize -> Tiny], ListPointPlot3D[Table[{i, Cos[i], Sin[i]}, {i, 0, 20, .1}], ImageSize -> Small]}Specify the width of the plot:
{ListPointPlot3D[Table[{i, Cos[i], Sin[i]}, {i, 0, 20, .1}], ImageSize -> 150], ListPointPlot3D[Table[{i, Cos[i], Sin[i]}, {i, 0, 20, .1}], AspectRatio -> 1.5, ImageSize -> 150]}Specify the height of the plot:
{ListPointPlot3D[Table[{i, Cos[i], Sin[i]}, {i, 0, 20, .1}], ImageSize -> {Automatic, 150}], ListPointPlot3D[Table[{i, Cos[i], Sin[i]}, {i, 0, 20, .1}], AspectRatio -> 2, ImageSize -> {Automatic, 150}]}Allow the width and height to be up to a certain size:
{ListPointPlot3D[Table[{i, Cos[i], Sin[i]}, {i, 0, 20, .1}], ImageSize -> UpTo[200]], ListPointPlot3D[Table[{i, Cos[i], Sin[i]}, {i, 0, 20, .1}], AspectRatio -> 2, ImageSize -> UpTo[200]]}Specify the width and height for a graphic, padding with space if necessary:
ListPointPlot3D[Table[{i, Cos[i], Sin[i]}, {i, 0, 20, .1}], ImageSize -> {200, 300}, Background -> StandardYellow]Setting AspectRatioFull will fill the available space:
ListPointPlot3D[Table[{i, Cos[i], Sin[i]}, {i, 0, 20, .1}], AspectRatio -> Full, ImageSize -> {200, 300}, Background -> StandardYellow]Use maximum sizes for the width and height:
{ListPointPlot3D[Table[{i, Cos[i], Sin[i]}, {i, 0, 20, .1}], ImageSize -> {UpTo[150], UpTo[100]}], ListPointPlot3D[Table[{i, Cos[i], Sin[i]}, {i, 0, 20, .1}], AspectRatio -> 2, ImageSize -> {UpTo[150], UpTo[100]}]}Use ImageSizeFull to fill the available space in an object:
Framed[Pane[ListPointPlot3D[Table[{i, Cos[i], Sin[i]}, {i, 0, 20, .1}], ImageSize -> Full, Background -> StandardYellow], {200, 100}]]Specify the image size as a fraction of the available space:
Framed[Pane[ListPointPlot3D[Table[{i, Cos[i], Sin[i]}, {i, 0, 20, .1}], AspectRatio -> Full, ImageSize -> {Scaled[0.5], Scaled[0.5]}, Background -> StandardYellow], {200, 200}]]IntervalMarkers (2)
Interval markers are bars by default:
zvar = Table[Around[Sin[x] Cos[y], 1], {x, -4, 4}, {y, -4, 4}];ListPointPlot3D[zvar]Use named IntervalMarkers:
xyzvar = Flatten[
Table[{x, y, Around[Sin[x] Cos[y], 1]}, {x, -4, 4}, {y, -4, 4}], 1];ListPointPlot3D[xyzvar, IntervalMarkers -> "Tubes"]IntervalMarkersStyle (2)
Interval markers are black by default:
zvar = Table[Around[Sin[x] Cos[y], 1], {x, -4, 4}, {y, -4, 4}];ListPointPlot3D[zvar]Specify the style for the bars:
xyzvar = Flatten[
Table[{x, y, Around[Sin[x] Cos[y], 1]}, {x, -4, 4}, {y, -4, 4}], 1];ListPointPlot3D[xyzvar, IntervalMarkersStyle -> Red]LabelingSize (3)
Images in callouts and labels are resized automatically by default:
ListPointPlot3D[RandomReal[1, {6, 3}] -> {[image], [image], [image] , [image], [image], [image]}, LabelingFunction -> Callout]Use LabelingSize to change the display size of labels:
ListPointPlot3D[RandomReal[1, {6, 3}] -> {[image], [image], [image] , [image], [image], [image]}, LabelingFunction -> Callout, LabelingSize -> 20]Textual labels are displayed at their full size:
SeedRandom[1];data = RandomInteger[100, {10, 3}] -> RandomWord[10]ListPointPlot3D[data, LabelingFunction -> Callout]ListPointPlot3D[data, LabelingFunction -> Callout, LabelingSize -> 40]LabelingTarget (7)
Labels are automatically placed to maximize readability:
ListPointPlot3D[IconizedObject[«data»]]ListPointPlot3D[IconizedObject[«data»], LabelingTarget -> All]Use a denser layout for the labels:
ListPointPlot3D[IconizedObject[«data»], LabelingTarget -> "Dense"]Show the quarter of the labels that are easiest to read:
ListPointPlot3D[IconizedObject[«data»], LabelingTarget -> 0.25]Only allow labels that are orthogonal to the points:
ListPointPlot3D[IconizedObject[«data»], LabelingTarget -> <|"AllowedLabelingPositions" -> "Sides"|>]Only allow labels that are diagonal to the points:
ListPointPlot3D[IconizedObject[«data»], LabelingTarget -> <|"AllowedLabelingPositions" -> "Corners"|>]Restrict labels to be above or to the right of the points:
ListPointPlot3D[IconizedObject[«data»], LabelingTarget -> <|"AllowedLabelingPositions" -> {"Right", "Top"}|>]Allow labels to obscure other points:
ListPointPlot3D[IconizedObject[«data»], LabelingTarget -> <|"AllowedOverlaps" -> {"Points"}|>]Allow labels to be clipped by the edges of the plot:
ListPointPlot3D[IconizedObject[«data»], LabelingTarget -> <|"AllowLabelClipping" -> True|>]PlotLegends (5)
ListPointPlot3D[{Table[Sin[i + j], {i, 0, 2Pi, 0.2}, {j, 0, 2Pi, 0.2}], Table[Cos[i + j], {i, 0, 2Pi, 0.2}, {j, 0, 2Pi, 0.2}]}]Generate a legend using labels:
ListPointPlot3D[{Table[Sin[i + j], {i, 0, 10, 0.25}, {j, 0, 10, 0.25}], Table[-Sin[i - j], {i, 0, 10, 0.25}, {j, 0, 10, 0.25}]}, PlotStyle -> {Red, Blue}, PlotLegends -> {Sin[x + y], -Sin[x - y]}]Generate a legend using placeholders:
ListPointPlot3D[{Table[Sin[j / 3], {i, 20}, {j, 20}], Table[-Sin[j / 3], {i, 20}, {j, 20}]}, PlotStyle -> {Blue, Orange}, PlotLegends -> Automatic]Use Placed to specify legend placement:
Table[ListPointPlot3D[{Table[Sin[j ^ 2 + i], {i, -Pi, Pi, 0.2}, {j, -2, 2, 0.2}], Table[Cos[j ^ 2 + i], {i, -Pi, Pi, 0.2}, {j, -2, 2, 0.2}]}, PlotLegends -> Placed[TraditionalForm /@ {Sin[x ^ 2 + y], Cos[x ^ 2 + y]}, pos], PlotLabel -> pos], {pos, {Above, Below}}]Table[ListPointPlot3D[{Table[Sin[Log[(i + j) ^ 2]], {i, 20}, {j, 20}], Table[Sin[-Log[(i + j) ^ 2]], {i, 20}, {j, 20}]}, PlotLegends -> Placed[{"data 1", "data 2"}, pos], PlotLabel -> pos], {pos, {Above, Below}}]Build a custom legend with BarLegend:
ListPointPlot3D[Table[Sin[j ^ 2 + i], {i, 0, Pi, 0.1}, {j, 0, Pi, 0.1}], ColorFunction -> (ColorData["Rainbow"][#1]&), PlotLegends -> Placed[BarLegend[{"Rainbow", {-1, 1}}], Below]]PlotRange (3)
Automatically compute the 
range:
ListPointPlot3D[Table[Exp[-x ^ 2 - y ^ 2], {x, -3, 3, .1}, {y, -3, 3, .1}], PlotStyle -> PointSize[Tiny]]Use all points to compute the range:
ListPointPlot3D[Table[Exp[-x ^ 2 - y ^ 2], {x, -3, 3, .1}, {y, -3, 3, .1}], PlotRange -> All, PlotStyle -> PointSize[Tiny]]Use an explicit 
range to emphasize features:
ListPointPlot3D[Table[y ^ 2 - x ^ 2, {x, -4, 4, 0.1}, {y, -4, 4, 0.1}], PlotRange -> {-2, 2}]PlotTheme (2)
Use a theme with simple ticks in a bold color scheme:
ListPointPlot3D[Table[Table[Cos[i + j ^ k], {i, 0, 3, 0.1}, {j, 0, 3, 0.1}], {k, {1, 2}}], PlotTheme -> "Web"]ListPointPlot3D[Table[Table[Cos[i + j ^ k], {i, 0, 3, 0.1}, {j, 0, 3, 0.1}], {k, {1, 2}}], PlotTheme -> "Web", PlotStyle -> {StandardBlue, StandardGreen}]RegionBoundaryStyle (3)
Show the region being plotted:
ListPointPlot3D[Table[Exp[-(i ^ 2 + j ^ 2)], {i, -2, 2, 0.1}, {j, -2, 2, 0.1}], RegionFunction -> Function[{x, y, z}, x < 0 || y > 0], DataRange -> {{-2, 2}, {-2, 2}}, PlotStyle -> PointSize[Small], RegionBoundaryStyle -> Automatic]Use None to not draw the region:
ListPointPlot3D[Table[Exp[-(i ^ 2 + j ^ 2)], {i, -2, 2, 0.1}, {j, -2, 2, 0.1}], RegionFunction -> Function[{x, y, z}, x < 0 || y > 0], DataRange -> {{-2, 2}, {-2, 2}}, PlotStyle -> PointSize[Small], RegionBoundaryStyle -> None]Use a custom RegionBoundaryStyle:
ListPointPlot3D[Table[Exp[-(i ^ 2 + j ^ 2)], {i, -2, 2, 0.1}, {j, -2, 2, 0.1}], RegionFunction -> Function[{x, y, z}, x < 0 || y > 0], DataRange -> {{-2, 2}, {-2, 2}}, PlotStyle -> PointSize[Small], RegionBoundaryStyle -> Directive[Yellow, Opacity[.8]]]RegionFunction (4)
ListPointPlot3D[Table[Sin[j ^ 2 + i], {i, 0, Pi, 0.05}, {j, 0, Pi, 0.05}], RegionFunction -> Function[{x, y, z}, Abs[z] > 0.5], PlotStyle -> PointSize[Small]]The region depends on DataRange:
data = Table[Sin[j ^ 2 + i], {i, 0, Pi, 0.1}, {j, 0, Pi, 0.1}];ListPointPlot3D[data, RegionFunction -> Function[{x, y, z}, Norm[{x, y}] < 4]]ListPointPlot3D[data, RegionFunction -> Function[{x, y, z}, Norm[{x, y}] < 4], DataRange -> {{0, Pi}, {0, Pi}}]Regions do not have to be connected:
ListPointPlot3D[Table[Sin[j ^ 2 + i], {i, 0, Pi, 0.05}, {j, 0, Pi, 0.05}], RegionFunction -> Function[{x, y, z}, 0 < Mod[x ^ 2 + y ^ 2, 2] < 1], DataRange -> {{0, Pi}, {0, Pi}}, PlotStyle -> PointSize[Small], RegionBoundaryStyle -> None]Use any logical combination of conditions:
ListPointPlot3D[Table[Exp[-(i ^ 2 + j ^ 2)], {i, -2, 2, 0.1}, {j, -2, 2, 0.1}], RegionFunction -> Function[{x, y, z}, x < 0 || y > 0], DataRange -> {{-2, 2}, {-2, 2}}, PlotStyle -> PointSize[Small]]ScalingFunctions (5)
By default, plots have linear scales in each direction:
SeedRandom[1];ListPointPlot3D[RandomChoice[Prime[Range[50]], {20, 3}]]Use a log scale in the 
direction:
SeedRandom[1];ListPointPlot3D[RandomChoice[Prime[Range[50]], {20, 3}], ScalingFunctions -> "Log"]Use a linear scale in the 
direction that shows smaller numbers at the top:
SeedRandom[1];ListPointPlot3D[RandomChoice[Prime[Range[50]], {20, 3}], ScalingFunctions -> "Reverse"]Use different scales in the 
, 
and 
directions:
SeedRandom[1];ListPointPlot3D[RandomChoice[Prime[Range[50]], {20, 3}], ScalingFunctions -> {"Log", "Log", "Reverse"}]Use a scale defined by a function and its inverse:
SeedRandom[1];ListPointPlot3D[RandomChoice[Prime[Range[50]], {20, 3}], ScalingFunctions -> {None, None, {-Log[#]&, Exp[-#]&}}]Ticks (6)
Ticks are placed automatically in each plot:
ListPointPlot3D[Table[Sin[j ^ 2 + i], {i, -2, 2, 0.1}, {j, -2, 2, 0.1}]]Use TicksNone to not draw any tick marks:
ListPointPlot3D[Table[Sin[j ^ 2 + i], {i, -2, 2, 0.1}, {j, -2, 2, 0.1}], Ticks -> None]Place tick marks at specific positions:
ListPointPlot3D[Table[Sin[j ^ 2 + i], {i, -2, 2, 0.1}, {j, -2, 2, 0.1}], Ticks -> {{5, 15, 25}, {5, 15, 25}, {-.9, 0, .9}}]Draw tick marks at the specified positions with the specified labels:
ListPointPlot3D[Table[Sin[j ^ 2 + i], {i, -2, 2, 0.1}, {j, -2, 2, 0.1}], Ticks -> {{{5, a}, {15, b}, {25, c}}, {{5, a}, {15, b}, {25, c}}, {{-.9, -A}, {0, 0}, {.9, A}}}]Specify tick marks with scaled lengths:
ListPointPlot3D[Table[Sin[j ^ 2 + i], {i, -2, 2, 0.1}, {j, -2, 2, 0.1}], Ticks -> {{{5, a, .05}, {15, b, .05}, {25, c, .05}}, {{5, a, .01}, {15, b, .01}, {25, c, .01}}, {{-.9, -A, .1}, {0, 0, .1}, {.9, A, .1}}}]Customize each tick with position, length, labeling and styling:
ListPointPlot3D[Table[Sin[j ^ 2 + i], {i, -2, 2, 0.1}, {j, -2, 2, 0.1}], Ticks -> {{{5, a, .05, Directive[Red]}, {15, b, .05, Directive[Red, Thick]}, {25, c, .05, Directive[Red, Thick, Dashed]}}, {{5, a, .05, Directive[Blue]}, {15, b, .05, Directive[Blue, Thick]}, {25, c, .05, Directive[Blue, Thick, Dashed]}}, {{-.9, -A, .1, Directive[Darker@Yellow, Thick]}, {0, 0, .1, Directive[Darker@Yellow, Thick, Dashed]}, {.9, A, .1, Directive[Darker@Yellow, Thick]}}}]TicksStyle (3)
By default, the ticks and tick labels use the same styles as the axis:
ListPointPlot3D[Table[Sin[j ^ 2 + i], {i, -2, 2, 0.1}, {j, -2, 2, 0.1}], AxesStyle -> Directive[Thick, Red]]Specify the overall tick style, including the tick labels:
ListPointPlot3D[Table[Sin[j ^ 2 + i], {i, -2, 2, 0.1}, {j, -2, 2, 0.1}], TicksStyle -> Directive[Bold, Red]]Specify the tick style for each of the axes:
ListPointPlot3D[Table[Sin[j ^ 2 + i], {i, -2, 2, 0.1}, {j, -2, 2, 0.1}], TicksStyle -> {Directive[Green, Bold], Directive[Bold, Red], Directive[Bold, Blue]}]Applications (1)
Sampling points for a three-dimensional integration:
points = Reap[NIntegrate[Boole[(x - 1)^2 + z^2 < 1] + Boole[(y - 1)^2 - z^2 < 1], {x, 0, 2}, {y, 0, 2}, {z, 0, 1}, EvaluationMonitor :> Sow[{x, y, z}]]][[2, 1]];ListPointPlot3D[points, BoxRatios -> Automatic, ColorFunction -> "Rainbow", PlotStyle -> PointSize[Small]]Properties & Relations (11)
Use ListPlot and ListLinePlot to plot heights in 2D:
{ListPlot[{1, 3, 4, 2, 7, 5}], ListLinePlot[{1, 3, 4, 2, 7, 5}]}{ListPlot[{{1, 5}, {2, 2}, {3, 9}, {4, 3}, {4, 7}, {5, 7}, {7, 1}, {8, 4}}], ListLinePlot[{{1, 5}, {2, 2}, {3, 9}, {4, 3}, {4, 7}, {5, 7}, {7, 1}, {8, 4}}]}Use ListLinePlot3D to plot curves through lists of points:
ListLinePlot3D[Table[{Cos[t], Sin[t], Sin[5t]}, {t, 0, 2Pi, 0.1}]]Plot curves through rows of heights in a table:
ListLinePlot3D[Table[Sin[j ^ 2 + i], {i, 0, 3, 0.25}, {j, 0, 3, 0.1}]]Use ListPlot3D to create surfaces from data:
ListPlot3D[Table[Sin[j ^ 2 + i], {i, 0, Pi, 0.1}, {j, 0, Pi, 0.1}]]Use Plot3D to visualize functions:
Plot3D[Sin[x y], {x, 0, 3}, {y, 0, 3}]Use ListLogPlot, ListLogLogPlot, and ListLogLinearPlot for logarithmic data plots:
ListLogPlot[Table[Binomial[25, k], {k, 0, 25}], Joined -> True]Use ListPolarPlot for polar plots:
ListPolarPlot[Table[{x, Sqrt[x]}, {x, 0, 2Pi, 0.1}], Joined -> True]Use DateListPlot to show data over time:
DateListPlot[{34, 51, 11, 5, 39, 47, 28, 42, 66, 13, 24, 31}, {2006, 1}, Joined -> True]Use ListContourPlot to create contours from continuous data:
ListContourPlot[Table[Sin[j ^ 2 + i], {i, 0, Pi, 0.1}, {j, 0, Pi, 0.1}]]Use ListDensityPlot to create densities from continuous data:
ListDensityPlot[Table[Sin[j ^ 2 + i], {i, 0, Pi, 0.1}, {j, 0, Pi, 0.1}]]Use ArrayPlot and MatrixPlot for arrays of discrete values:
ArrayPlot[Table[GCD[i, j], {i, 1, 20}, {j, 1, 20}]]Use ParametricPlot for parametric curves:
{ParametricPlot[{Cos[θ], Sin[θ]}, {θ, 0, 2Pi}], ListLinePlot[Table[{Cos[θ], Sin[θ]}, {θ, 0, 2Pi, 0.1}], AspectRatio -> 1]}Neat Examples (2)
ListPointPlot3D[Table[Table[{t, Cos[t + s Pi / 2], Sin[t + s Pi / 2]}, {t, 0, 5Pi, .2}], {s, 4}], BoxRatios -> Automatic]ListPointPlot3D[Table[Table[(4Pi - t){Cos[t + s Pi / 2], Sin[t + s Pi / 2], 0} + {0, 0, 2t}, {t, 0, 4Pi, .1}], {s, 4}], Filling -> Bottom, ColorFunction -> "Rainbow", BoxRatios -> Automatic, FillingStyle -> Directive[LightGreen, Thick, Opacity[.1]]]
Wolfram Research (2007), ListPointPlot3D, Wolfram Language function, https://reference.wolfram.com/language/ref/ListPointPlot3D.html (updated 2026).
Text
Wolfram Research (2007), ListPointPlot3D, Wolfram Language function, https://reference.wolfram.com/language/ref/ListPointPlot3D.html (updated 2026).
CMS
Wolfram Language. 2007. "ListPointPlot3D." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2026. https://reference.wolfram.com/language/ref/ListPointPlot3D.html.
APA
Wolfram Language. (2007). ListPointPlot3D. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ListPointPlot3D.html